;  Copyright (C) 2008 - 2014 Cesar Mauri Loba
;
;   Permission is hereby granted, free of charge, to any person obtaining a
;   copy of this software and associated documentation files (the "Software"),
;   to deal in the Software without restriction, including without limitation
;   the rights to use, copy, modify, merge, publish, distribute, sublicense,
;   and/or sell copies of the Software, and to permit persons to whom the
;   Software is furnished to do so, subject to the following conditions:
;
;   The above copyright notice and this permission notice shall be included in
;   all copies or substantial portions of the Software.
;
;   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
;   IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
;   FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
;   AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
;   LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
;   FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
;   DEALINGS IN THE SOFTWARE.
;
;   Inno Setup installer script
;

#define APPNAME			"Enable Viacam"
#define APPNAME_SHORT	"eViacam"
#define VERSION         "@VERSION@"
#define PUBLISHER		"@PUBLISHER@"
#define VERTEXT			"v@VERSION@"
#define APPBIN			"eViacam.exe"
#define COPYRIGHT		"@COPYRIGHT@"

[Setup]
AppName={#APPNAME}
AppVerName={#APPNAME} {#VERSION}
AppPublisher={#PUBLISHER}
AppCopyright={#COPYRIGHT} {#PUBLISHER}
AppVersion={#VERSION}
AppUpdatesURL=http://viacam.org
AppPublisherURL=http://www.crea-si.com

VersionInfoTextVersion={#VERTEXT}
VersionInfoCopyright={#COPYRIGHT} {#PUBLISHER}
VersionInfoVersion={#VERSION}
VersionInfoCompany={#PUBLISHER}
VersionInfoDescription=Installer for {#APPNAME}
VersionInfoProductName={#APPNAME}
VersionInfoProductVersion={#VERSION}

SourceDir=..
DefaultDirName={pf}\{#APPNAME}
UninstallDisplayIcon={app}\bin\{#APPBIN}
DefaultGroupName={#APPNAME}
LicenseFile=COPYING
OutputBaseFilename={#APPNAME_SHORT}-{#VERSION}
PrivilegesRequired=poweruser

MinVersion=0,5.0.2195sp3
UsePreviousSetupType=true
UsePreviousGroup=false
DirExistsWarning=yes
Compression=lzma2/max
InternalCompressLevel=max
ShowLanguageDialog=yes

AppID={{BF2FC5F6-EC88-4CA5-BD83-DC6613FD077D}
OutputDir=win32
InfoAfterFile=win32\Info\InfoAfter.rtf
SetupIconFile=win32\installer.ico

[Files]
Source: win32\Release\bin\*; DestDir: {app}\bin; Flags: recursesubdirs ignoreversion
Source: doc\*.png; DestDir: {app}\bin; Flags: ignoreversion
Source: doc\*.wav; DestDir: {app}\bin; Flags: ignoreversion
Source: THANKS; DestDir: {app}\bin; DestName: THANKS
Source: COPYING; DestDir: {app}\doc; DestName: license.txt
Source: NEWS; DestDir: {app}\doc; DestName: NEWS.txt
Source: doc\*.txt; DestDir: {app}\doc; Flags: recursesubdirs ignoreversion
Source: doc\*.png; DestDir: {app}\doc; Flags: recursesubdirs ignoreversion
Source: README; DestDir: {app}\doc; Flags: ignoreversion; DestName: README.txt
Source: doc\help\*; DestDir: {app}\bin\help; Flags: recursesubdirs ignoreversion

[Tasks]
Name: desktopicon; Description: {cm:CreateDesktopIcon}

[Icons]
Name: {group}\{#APPNAME}; Filename: {app}\bin\{#APPBIN}; WorkingDir: {app}\bin
Name: {group}\{cm:UninstallProgram,{#APPNAME}}; Filename: {uninstallexe}
Name: {group}\{#APPNAME} help; Filename: {app}\bin\help\en\contents.htm
Name: {group}\Release notes; Filename: {app}\doc\NEWS.txt
Name: {group}\{#APPNAME} ayuda; Filename: {app}\bin\help\es\contents.htm; Languages: Castellano
Name: {group}\{#APPNAME} ajuda; Filename: {app}\bin\help\ca\contents.htm; Languages: Catala
Name: {group}\{#APPNAME} axuda; Filename: {app}\bin\help\gl\contents.htm; Languages: Galego
Name: {group}\{#APPNAME} Hilfe; Filename: {app}\bin\help\de\contents.htm; Languages: Deutsch
Name: {group}\{#APPNAME} Помощь; Filename: {app}\bin\help\ru\contents.htm; Languages: Russian

Name: {commondesktop}\eViacam; Filename: {app}\bin\eViacam.exe; WorkingDir: {app}\bin; Tasks: desktopicon

[Run]
;Filename: {app}\doc\README.txt; Flags: postinstall shellexec
Filename: {app}\doc\NEWS.txt; Flags: postinstall shellexec skipifsilent

[Components]

[Languages]
Name: English; MessagesFile: compiler:Default.isl
Name: Catala; MessagesFile: compiler:Languages\Catalan.isl; InfoAfterFile: win32\Info\InfoAfter-ca.rtf
Name: Castellano; MessagesFile: compiler:Languages\Spanish.isl; InfoAfterFile: win32\Info\InfoAfter-es.rtf
Name: Deutsch; MessagesFile: compiler:Languages\German.isl; InfoAfterFile: win32\Info\InfoAfter-de.rtf
Name: Galego; MessagesFile: compiler:Languages\Galician.isl
Name: Italiano; MessagesFile: compiler:Languages\Italian.isl
Name: Turkish; MessagesFile: compiler:Languages\Turkish.isl; InfoAfterFile: win32\Info\InfoAfter-tr.rtf
Name: Occitan; MessagesFile: compiler:Languages\Occitan.isl
Name: French; MessagesFile: compiler:Languages\French.isl; InfoAfterFile: win32\Info\InfoAfter-fr.rtf
Name: Arabic; MessagesFile: compiler:Languages\Arabic.isl
Name: Hebrew; MessagesFile: compiler:Languages\Hebrew.isl
Name: Russian; MessagesFile: compiler:Languages\Russian.isl; InfoAfterFile: win32\Info\InfoAfter-ru.rtf
Name: Portuguese; MessagesFile: compiler:Languages\BrazilianPortuguese.isl
Name: Japanese; MessagesFile: compiler:Languages\Japanese.isl
Name: Greek; MessagesFile: compiler:Languages\Greek.isl
Name: Lithuanian; MessagesFile: compiler:Languages\Lithuanian.isl
Name: Chinese_TW; MessagesFile: compiler:Languages\ChineseTraditional.isl
Name: Chinese_CN; MessagesFile: compiler:Languages\ChineseSimplified.isl

[Registry]
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: english; Languages: English
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: spanish; Languages: Castellano
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: catalan; Languages: Catala
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: gl; Languages: Galego
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: it; Languages: Italiano
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: tr; Languages: Turkish
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: de; Languages: Deutsch
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: oc; Languages: Occitan
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: fr; Languages: French
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: ar; Languages: Arabic
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: he; Languages: Hebrew
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: ru; Languages: Russian
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: Portuguese (Brazilian); Languages: Portuguese
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: Japanese; Languages: Japanese
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: Greek; Languages: Greek
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: Lithuanian; Languages: Lithuanian
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: zh_TW; Languages: Chinese_TW
Root: HKCU; Subkey: Software\eviacam\settings; ValueType: string; ValueName: language; ValueData: zh_CN; Languages: Chinese_CN

[_ISTool]
Use7zip=false
UseAbsolutePaths=false
