newaxes Creates a new Axes entity

## Syntax

                a = newaxes()
                a = newaxes(h)

## Arguments

h

  Optional handle of the graphic parent of the new axes, of type `Figure` or `Uicontrol` of style `Frame`. By default, the current figure is used.

a

  Handle on the newly created Axes entity

## Description

`newaxes()` is used to create a new `Axes` entity (see graphics_entities) in the current figure or in the given figure or uicontrol frame.

The properties of this entity are inherited from the `default_axes` entity (see gda)

`newaxes(h)` creates the axes in the frame uicontrol or figure whose handle is `h`.

## Examples

    clf()
    a1 = newaxes();
    a1.axes_bounds = [0,0,1.0,0.5];
    t = 0:0.1:20;
    plot(t,acosh(t),'r')
    a2 = newaxes();
    a2.axes_bounds = [0,0.5,1.0,0.5];
    x = 0:0.1:4;
    plot(x,sinh(x))
    legend('sinh')

    sca(a1); //make first axes current
    plot(t, asinh(t), 'g')
    legend(['acosh','asinh'])

The following example uses `newaxes(h)`

    // Create a new figure
    f = figure("layout", "gridbag", ...
        "toolbar", "none", ...
        "menubar", "none", ...
        "backgroundcolor", [1 1 1]);

    // Create the frames where each graph is put
    c = createConstraints("gridbag", [1 1 1 1], [1 1], "both");
    top_left = uicontrol(f, "style", "frame","constraints", c);

    c.grid = [2 1 1 1];
    top_right = uicontrol(f, "style", "frame", "constraints", c);

    c.grid = [1 2 2 2];
    bottom = uicontrol(f, "style", "frame", "constraints", c);

    // Create the axes in each frame
    a_tl = newaxes(top_left);
    a_tr = newaxes(top_right);
    a_bt = newaxes(bottom);

    // Plot in the frames
    X = (1:100) ./ 50;
    plot(a_tl, X, X, "r");
    plot(a_tr, X, cos(2 * %pi * 3 * X), "g");
    plot(a_bt, X, exp(X), "b");

    title(a_tl, "a line");
    title(a_tr, "a cosine");
    title(a_bt, "the exponential");

## See also

- Multiscaled plots
- subplot
- xsetech
- gda
- sca

## History

5.5.0 newaxes(h) can target a uicontrol frame or a given figure.