gda Retorna o manipulador dos eixos padrões.

## Seqüência de Chamamento

    a = gda()
                a = get("default_axes")

## Parâmetros

a

  o manipulador dos eixos padrões.

## Descrição

Os eixos padrões são uma entidade gráfica (entidade Axes) que nunca é desenhada. Ela usada como referência para os valores de propriedades padrões dos eixos. Estes valores de propriedades padrões são usados para inicializar novos eixos dentro de figuras.

A função `gda` retorna o manipulador dos eixos padrões. O usuário pode utilizar este manipulador para ajustar ou obter os valores padrões de propriedades dos eixos.

Note que uma entidade gráfica padrão equivalente também existe para entidades Figure (ver `gdf`).

## Exemplos

    a=gda() // obtendo o manipulador dos eixos modelos
    // ajustando suas propriedades
    a.box="off";
    a.foreground=2;
    a.labels_font_size=3;
    a.labels_font_color=5;
    a.sub_tics=[5 5 3];
    a.x_location="top";

    //os eixos modelos são agora usados
    subplot(211) //criando uma nova entidade Axes
    plot2d()

    // veja outros modelos de propriedades
    a.background=color('gray')
    a.grid=[5 5 5];
    subplot(212)
    t=0:0.1:5*%pi;
    plot2d(sin(t),cos(t))

    set(a,"default_values",1); // retornando para os valores padrões do modelo
                               // ver a função sda()
    clf()
    plot2d(sin(t),cos(t))

## Ver Também

- gdf
- sda
- sdf
- clf
- gca
- get
- graphics_entities