zoom_rect Amplia uma seleção da figura gráfica corrente

## Seqüência de Chamamento

    zoom_rect()
                zoom_rect(rect)
                zoom_rect(h)
                zoom_rect(h,rect)

## Parâmetros

rect

  vetor de tamanho 4 `[xmin,ymin,xmax,ymax]` fornece o retângulo a ser ampliado

h

  manipulador gráfico do tipo Figure ou Axes. Especifica sobre que eixos se realizará a ampliação.

## Descrição

`zoom_rect` é a função utilizada para realizar ampliações dentro de um conjunto de objetos Axes.

O argumento de entrada `h` especifica sobre que eixos se realizará a ampliação. Se `h` for um manipulador do tipo Figure, então a ampliação ocorrerá sobre seus galhos Axes. Se `h` for um manipulador Axes, a ampliação será aplicada apenas sobre este objeto. Se `h` não for especificado, então a ampliação será aplicada sobre a entidade Figure corrente.

Se o argumento de entrada `rect` for especificada, então a propriedade `zoom_box` dos eixos ampliados será modificada por este argumento (ver axes_properties). Seus limites ao longo dos eixos X e Y serão substituídos por `rect`. Se `rect` não for especificado zoom_rect será uma ampliação interativa. Requer-se que o usuário selecione um retângulo utilizando o mouse. A nova propriedade `zoom_box` dos eixos ampliados é então computada encontrando-se as interseções do retângulo com suas caixas de eixos.

## Exemplos

    clf()
    x=0:0.01:6*%pi;
    plot2d(x,sin(x.^2))
    zoom_rect([16,-1,18,1])
    //mais zoom
    zoom_rect([16,0,16.2,1])
    //de volta ao original
    unzoom()
    // ajustando o zoom através de axes_properties
    a=gca();
    a.zoom_box=[16,0,16.2,1];
    a.zoom_box=[];

    //ajustando zoom de sub-esboços
    clf()
    x=0:0.01:6*%pi;
    subplot(211)
    plot2d(x,cos(x))
    subplot(212)
    plot2d(x,cos(2*x))
    rect=[3 -2 7 10]; //um retângulo especificado nas coordenadas dos eixos correntes (os últimos)
    zoom_rect(rect)
    unzoom()
    //ajustando os eixos subjascentes globais como sendo os correntes
    f=gcf();set('current_axes',f.children($))
    rect=[0.4 0 0.6 1] //um retângulo especificado em razão do tamanho da janela
    zoom_rect(rect)
    rect=[0.4 0.2 0.6 0.8]; //um retângulo especificado em razão do tamanho da janela
    zoom_rect(rect)

    // ampliação interativa sob a figura corrente
    zoom_rect();
    // ou
    zoom_rect(gcf());

## Ver Também

- unzoom
- axes_properties