bar Histograma de barras

## Seqüência de Chamamento

                bar(x, y)
                bar(x, y, width, colors, style)
                bar(x, y [,width] [,colors] [,style])
                bar(h, x, y ..)

## Parâmetros

h

  manipulador de eixos, (padrão: h=gca() ).

y

  scalar, vector of size N, or matrix N*M of real numbers or encoded integers, with

  - N : number of groups (each group of bars gathered on/around an x position)
  - M : number of categories in each group
x

  escalar real ou um vetor de tamanho N, (padrão: se y é um vetor, então x is é um vetor e o comprimento de x é igual ao comprimento de y. Se y é uma matriz, então x é um vetor e o comprimento de x é igual ao número de linhas de y)

width

  (opcional), escalar real, define a largura (uma porcentagem do espaço disponível) para a barra (padrão: 0.8, i.e 80%).

colors

  (opcional) Single string or vector of M strings: colors names (among predefined ones) or "#RRGGBB" hexadecimal codes of categories colors. Default = default plot() colors series, starting with "blue".

style:

  string, 'grouped' ou 'stacked' (padrão: 'grouped').

## Descrição

`bar(y,...) :` se y é um vetor então a função bar desenha uma poligonal que tem `polyline_style` tipo 6. Se y for um vetor, desenha o vetor y versus o vetor 1:size(y,'*') . Se y for uma matriz N*M, bar desenha M poligonais (tipo 6), cada poligonal corresponde a uma coluna de y versus o vetor x=1:size(y,1).

`bar(x,y,...) :` se y for um vetor, então a função bar desenha uma poligonal que tem `polyline_style` tipo 6, onde comprimento de x = comprimento de y. Se y é uma matriz NxM então a função bar desenha M poligonais que possuem tipo 6. Cada poligonal corresponde a uma coluna de y versus o vetor x.

`bar(h,...) :` define os eixos correntes onde o desenho é feito.

`bar(...,width,...) :` define a largura da(s) barra(s) em porcentagem (geralmente: 0<width<=1).

`bar(...,style,...) :` define como as barras serão desenhadas. Se y é uma matriz NxM (então temos M poligonais de tipo 6), então há dois modos de se desenhar as M barras. A opção style= 'grouped' permite centrar as M poligonais versus cada componente de x, e a opção style = 'stacked' permite empilhá-las.

`bar(...,colors,...) :` define a cor da barra.

Se há várias chamadas a bar(), a função `barhomogenize` permite homogeneizar a largura e estilo de todas as barras (i.e poligonais do tipo 6) inclusas nos eixos correntes.

## Exemplos

    // primeiro exemplo: desenhando uma barra (i.e uma poligonal com polyline_style =6) com
    // width=0.5 e colors='yellow' e style='grouped', x=1:length(y).
    scf(0);
    y=[1 -3 5];
    bar(y,0.5,'yellow');

    // segundo exemplo: desenhando 3 barras (i.e três poligonais com polyline_style =6), style='grouped'
    scf(1);
    x=[1 2 5]; y=[1  -5 6;3 -2 7;4  -3 8];
    bar(x,y);

    // terceiro exemplo: style='stacked'.
    scf(2);
    x=[1 2 5]; y=[1 4 7;2 5 8;3 6  9];
    bar(x,y,'stacked');

    // quarto exemplo: width=0.2;colors='green', style='grouped'
    scf(3);
    x=[1 2 5]; y=[1 4 7;2 5 8;3 6 9];
    bar(x,y,0.2,'green');

## Ver Também

- barh
- barhomogenize
- histplot
- plot
- named colors
- polyline_properties
- bar3d

## Histórico

6.0.1

- A vector of M colors can now be provided, one for each category.
- Available colors are no longer restricted to the 10 major colors. All the predefined colors names can now be used.
- Colors can now be specified also by their "#RRGGBB" hexadecimal codes.