close Закрывает графические окна, панели прогресса или состояния, браузер справки, xcos, браузер переменных или редактор.

## Синтаксис

                close
                close(H)
                close help
                close xcos
                close xcos!
                close editvar
                close browsevar

## Аргументы

H

  вектор дескрипторов графических окон или идентификаторов, либо дескрипторов панели прогресса и панели состояния.

## Описание

close закрывает текущее графическое окно (если есть).

close(H) закрывает графические окна,панели состояния или прогресса, чьи индикаторы или индексы находятся в `H`.

close help закрывает браузер справки.

close browsevar закрывает браузер переменных.

close editvar закрывает редактор переменных (он не должен быть встроенным).

close xcos закрывает все открытые окна xcos. Если какие-то диаграммы имеют несохранённые изменения, то у пользователя запросят подтверждение.

close xcos! принудительное закрытие всех открытых окон xcos без запроса какого-либо подтверждения.

## Примеры

    // создаём окно номер 1.
    h = scf();
    // разместим чёткий текст в окне 1
    uicontrol( h, 'style','text', ...
                  'string','scilab is great', ...
                  'position',[50 70 100 100], ...
                  'fontsize',15);
    // создаём окно номер 2
    scf();
    // разместим текст в окне 2
    uicontrol( 'style','text', ...
               'string','Really great', 'position',[50 70 100 100], 'fontsize',15);

    close();   // закрываем текущее графическое окно (т.е. номер 2)
    close(h);  // закрываем окно 1

    // создаём панель прогресса
    wid1=progressionbar("Message");
    // закроем его
    close(wid1);

    // Создаём и закрываем несколько окон за раз:
    scf(111); plot
    scf(25); plot2d
    gcf().figure_position(1) = 500;
    scf(200); param3d
    gcf().figure_position(1) = 700;
    sleep(5000);         // смотрим на них!
    close([25 200 111])  // конец!

    // Вы читаете этот пример в браузере справки. Теперь до свидания:
    close help

    xcos
    sleep(5000)
    close xcos

    browsevar
    sleep(5000)
    close browsevar

    a = rand(3,5);
    editvar a
    sleep(5000)
    close editvar

## Смотрите также

- delete
- exit
- mclose
- h5close

## История

6.1.1

- Теперь принимаются идентификаторы нескольких окон.
- Расширение до `close help`, `close xcos`, `close xcos!`, `close browsevar` и `close editvar`