Sgrayplot esboço 2d suave de uma superfície utilizando cores

## Seqüência de Chamamento

    Sgrayplot(x,y,z,<opt_args>)
                Sgrayplot(x,y,z [,strf, rect, nax, zminmax, colminmax, mesh, colout])

## Parâmetros

x,y

  vetores linhas de reais de tamanhos n1 e n2.

z

  matriz de reais de tamanho (n1,n2). `z(i,j)` é o valor da superfície no ponto (x(i),y(j)).

<opt_args>

  representa uma seqüência de declarações `key1=value1,key2=value2`,... onde `key1`, `key2,...` podem ser um dos seguintes: strf, rect, nax, zminmax, colminmax, mesh, colout.

strf

  é um string de comprimento 3 `"xyz"` (por padrão `strf= "081"`)

  x

    controla a exibição de legendas

    x=0

      sem legendas.

    x=1

      legendas são exibidas. Elas são dadas pelo argumento opcional `leg`.

  y

    controla a computação dos intervalos de coordenadas reais a partir dos valores mínimos requeridos. Intervalos reais podem ser maiores que os requerimentos mínimos.

    y=0

      sem computação, o esboço utiliza a escala anterior (ou padrão)

    y=1

      a partir do argumento rect

    y=2

      a partir dos valores mínimo/máximo dos dados x e y

    y=3

      construídos para uma escala isométrica a partir do argumento rect

    y=4

      construídos para uma escala isométrica a partir dos valores mínimo/máximo dos dados x e y

    y=5

      aumentados para obtenção de bons eixos a partir do argumento rect

    y=6

      aumentados para obtenção de bons eixos a partir dos valores mínimo/máximo dos dados x e y

    y=7

      como y= 1 mas os anteriores são redesenhados para se utilizar a nova escala

    y=8

      lcomo y= 2 mas os anteriores são redesenhados para se utilizar a nova escala

  z

    controla a exibição de informação na moldura ao redor do esboço. Se eixos são requeridos, o número de tiques pode ser especificado pelo argumento opcional `nax`.

    z=0

      nada é desenhado ao redor do esboço.

    z=1

      eixos são desenhados, o eixo y é exibido à esquerda.

    z=2

      o esboço é cercado por uma caixa sem tiques.

    z=3

      eixos são desenhados, o eixo y é exibido à direita.

    z=4

      eixos são desenhados centrados no meio da caixa de moldura.

    z=5

      eixos são desenhados cruzando-se no ponto `(0,0)`. Se o ponto `(0,0)` não estiver dentro da moldura, os eixos não aparecerão no gráfico.

rect

  este argumento é utilizado quando o segundo caractere y do argumento `strf` é 1, 3 ou 5. É um vetor linha de tamanho quatro e fornece a dimensão da moldura: `rect=[xmin,ymin,xmax,ymax]`.

nax

  este argumento opcional é utilizado quando o terceiro caractere z do argumento `strf` ié 1. É um vetor linha de quatro entradas `[nx,Nx,ny,Ny]` onde `nx` (`ny`) é o número de sub-graduações no eixo x (y) axis e `Nx` (`Ny`) é o número de graduações no eixo x (y).

zminmax, colminmax, mesh, colout

  ver fec.

## Descrição

`Sgrayplot` é o mesmo que `grayplot` mas o esboço é suavizado. A função `fec` é utilizada para suavização. A superfície é esboçada assumindo-se que é linear em um conjunto de triângulos construídos a partir do grid (aqui, com n1=5, n2=3):

    _____________
    | /| /| /| /|
    |/_|/_|/_|/_|
    | /| /| /| /|
    |/_|/_|/_|/_|

A função colorbar pode ser utilizada para se visualizar a escala de cores.

O parâmetro `zminmax` é útil para propósitos de animação (veja um exemplo depois) e o parâmetro `colminmax` permite que o usuário escolha uma parte do mapa de cores corrente (ver a página de ajuda de fec).

Entre com o comando `Sgrayplot()` para visualizar uma demonstração.

## Exemplos

    // exemplo #1
    x=-10:10; y=-10:10;m =rand(21,21);
    clf()
    gcf().color_map = hot(64);
    Sgrayplot(x,y,m, strf="011", rect=[-20,-20,20,20])

    // exemplo #2
    t=-%pi:0.1:%pi; m=sin(t)'*cos(t);
    clf()
    gcf().color_map = jet(64);
    colorbar(-1,1)
    Sgrayplot(t,t,m, strf="041")

    // exemplo #3: exibindo animação de cos(t)*sin(x)sin(y).
    n = 30;
    nt = 100;
    x = linspace(0,2*%pi,n);
    y = linspace(0,%pi,n/2);
    z = sin(x')*sin(y);
    t = linspace(0,4*%pi,nt);
    show_window(); clf()
    f=gcf();
    f.color_map=jet(64);
    colorbar(-1,1)
    Sgrayplot(x,y,cos(t(1))*z, strf="042", zminmax=[-1,1])
    c=gce(),e=c.children
    xtitle("Olhos de Kaa")
    for i = 1:nt
      e.data(:,3)=matrix(cos(t(i))*z,-1,1);
    end

## Ver Também

- fec
- fgrayplot
- grayplot
- Sfgrayplot
- colorbar