# the lorenz equations
# with some fancy graphics options
x'=s*(-x+y)
y'=r*x-y-x*z
z'=-b*z+x*y
par r=27,s=10,b=2.66
init x=-7.5,y=-3.6,z=30
# now add some projection planes for 2D plote
aux x2=xplane
aux y2=yplane
aux z2=zplane
par xplane=-35,yplane=60,zplane=-10
# set up the numerics
@ total=50,dt=.02
# set up 3D plot 
@ xplot=x,yplot=y,zplot=z,axes=3d
# tell XPP there are 4 plots altogether 
@ nplot=4
# here are the 3 projections
@ xp2=x,yp2=y,zp2=z2
@ xp3=x,yp3=y2,zp3=z
@ xp4=x2,yp4=y,zp4=z
# set up the 3D window
@ xmin=-40,xmax=18,ymin=-24,ymax=64,zmin=-12,zmax=45
@ xlo=-1.4,ylo=-1.7,xhi=1.7,yhi=1.7
# and rotate the plot a bit so it looks nice
@ theta=35
done
