Tartalom

# ÁTLAGHA függvény

Visszaadja egy tartomány adott feltételnek megfelelő összes cellájának számtani közepét. Az ÁTLAGHA függvény összeadja a logikai tesztnek megfelelő összes találatot, és elosztja ezt az összeget a kiválasztott értékek számával.

Ez a funkció a LibreOffice 4.0 óta érhető el.

### Szintaxis

ÁTLAGHA(tartomány; feltételek [; átlag_tartomány ])

tartomány - kötelező argumentum. Egy tömb, nevesített tartomány neve, átlagolandó számokat tartalmazó sor vagy oszlop fejléce, vagy számok vagy a feltétel szövege.

Criterion: A criterion is a single cell Reference, Number or Text. It is used in comparisons with cell contents.

A reference to an empty cell is interpreted as the numeric value 0.

A matching expression can be:

- A Number or Logical value. A matching cell content equals the Number or Logical value.

- A value beginning with a comparator (<, <=, =, >, >=, <>).

  For =, if the value is empty it matches empty cells.

  For <>, if the value is empty it matches non-empty cells.

  For <>, if the value is not empty it matches any cell content except the value, including empty cells.

  Note: "=0" does not match empty cells.

  Az = és <> esetében, ha az érték nem üres és nem értelmezhető számtípusként vagy annak egyik altípusaként, és a Az = és a <> keresési feltétel csak teljes cellán alkalmazható tulajdonság be van jelölve, az összehasonlítás a teljes cellatartalommal történik, ha nincs jelölve, akkor a mező bármely, a kritériumoknak megfelelő részével történik. Az = és <> esetében, ha az érték nem üres és nem értelmezhető számtípusként vagy annak valamelyik altípusaként, akkor érvényes.

- Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

átlag_tartomány - elhagyható. Értékek tartománya az átlag kiszámításához.

If the Average_Range is not specified, Range is used for both, the calculation of the mean and the search according to the condition. If Average_Range is specified, the Range is used only for the condition test, while Average_Range is used for the average calculation.

Ez a függvény az Open Document Format for Office Applications (OpenDocument) szabvány 1.2-es verziójának része. (ISO/IEC 26300:2-2015)

Ha az átlag kiszámítására használt értékek tartományában egy cella üres vagy szöveget tartalmaz, akkor az ÁTLAGHA függvény figyelmen kívül hagyja.
Ha a teljes tartomány üres, csak szöveget tartalmaz, vagy egyik érték sem felel meg a feltételnek (vagy ezek tetszőleges kombinációja), akkor a függvény #ZÉRÓOSZTÓ! hibát ad vissza.

#### Példa

Figyelje meg a következő táblázatot

| A | B | C
1 | Termék neve | Eladások | Bevétel
2 | tollbetét | 20 | 65
3 | toll | 35 | 85
4 | jegyzőkönyv | 20 | 190
5 | könyv | 17 | 180
6 | tolltartó | nem | nem

In all examples below, ranges for calculation contain the row #6, which is ignored because it contains text.

#### Egyszerű használat

=ÁTLAGHA(B2:B6;"<35")

Kiszámítja a B2:B6 tartomány azon értékeinek átlagát, amelyek 35-nél kisebbek. A visszaadott érték 19, mert a 2. sor nem vesz részt a számításban.

=ÁTLAGHA(B2:B6;"<"&MAX(B2:B6))

Kiszámítja ugyanezen tartomány azon értékeinek átlagát, amelyek a tartomány legnagyobb értékénél kisebbek. A visszaadott érték 19, mert a legnagyobb érték (a 2. sorban) nem vesz részt a számításban.

=ÁTLAGHA(B2:B6;">"&KICSI(B2:B6;1))

Kiszámítja ugyanezen tartomány azon értékeinek átlagát, amelyek a tartomány legkisebb értékénél nagyobbak. A visszaadott érték 25, mert az első legkisebb érték (a 4. sorban) nem vesz részt a számításban.

#### Az átlag_tartomány használata

=ÁTLAGHA(B2:B6;"<35";C2:C6)

A függvény megkeresi a 35-nél kisebb értékeket a B2:B6 tartományban, és kiszámítja a megfelelő értékek átlagát a C2:C6 tartományból. Visszatérési értéke 145, mert a második sor nem vesz részt a számolásban.

=ÁTLAGHA(B2:B6;">"&MIN(B2:B6);C2:C6)

A függvény megkeresi a B2:B6 tartomány legkisebb értékétől nagyobb értékeket a B2:B6 tartományban, és kiszámítja a megfelelő értékek átlagát a C2:C6 tartományból. A visszaadott érték 113,3, mert a negyedik sor (ahol a B2:B6 tartomány legkisebb értéke van) nem vesz részt a számításban.

=ÁTLAGHA(B2:B6;"<"&NAGY(B2:B6;2);C2:C6)

A függvény megkeresi a B2:B6 tartomány második legnagyobb értékétől kisebb értékeket a B2:B6 tartományban, és kiszámítja a megfelelő értékek átlagát a C2:C6 tartományból. A visszaadott érték 180, mert csak a negyedik sor vesz részt a számításban.

#### Reguláris kifejezések használata

=ÁTLAGHA(A2:A6;"toll";B2:B6)

A függvény megkeresi az A2:A6 tartományban a pontosan a „toll” szót tartalmazó cellákat, és kiszámítja a B2:B6 tartományban megfelelő értékek átlagát. A 35-öt adja vissza, mert csak a második sor vesz részt a számításban. A keresés az A2:A6 tartományban történik, de az értékek a B2:B6 tartományból kerülnek visszaadásra.

=ÁTLAGHA(A2:A6;"toll.*";B2:B6)

A függvény megkeresi az A2:A6 tartományban „toll” szóval kezdődő és tetszőleges karakterekre végződő értékű cellákat, és kiszámítja a megfelelő értékek átlagát a B2:B6 tartományban. A visszaadott érték 27,5, mert a „tolltartó” is megfelel a feltételnek, így az első két sor vesz részt a számításban.

=ÁTLAGHA(A2:A6;".*könyv.*";B2:B6)

A függvény megkeresi az A2:A6 tartományban „könyv” szót tartalmazó, és tetszőleges más karakterekkel kezdődő és végződő értékű cellákat, és kiszámítja a megfelelő értékek átlagát a B2:B6 tartományban. A visszaadott érték 18,5, mert csak a harmadik és negyedik sor vesz részt a számításban.

#### Hivatkozás cellára feltételként

Ha egyszerűen szeretne feltételt módosítani, akkor érdemes egy külön cellában megadni, és erre a cellára mutató hivatkozást használni az ÁTLAGHA függvény feltételében.

=ÁTLAGHA(A2:A6;".*"&E2&".*";B2:B6)

A függvény megkeresi az A2:A6 tartományban az E2 cellában megadott karaktereket tartalmazó, és tetszőleges más karakterekkel kezdődő és végződő értékű cellákat, és kiszámítja a megfelelő értékek átlagát a B2:B6 tartományban. Ha az E2 = könyv, a visszaadott érték 18,5.

=ÁTLAGHA(B2:B6;"<"&E2;C2:C6)

A függvény megkeresi a B2:B6 tartományban az E2 cellában megadottól kisebb értékű cellákat, és kiszámítja a megfelelő értékek átlagát a C2:C6 tartományban. Ha az E2 = 35, a visszaadott érték 145.

Kapcsolódó témakörök

AVERAGEIF wiki page.

ÁTLAG, ÁTLAG2, ÁTL.ELTÉRÉS

DARABHATÖBB, MINHA, MAXHA, ÁTLAGHATÖBB, SZUMHATÖBB

Reguláris kifejezések listája