PERLSTYLE(7)

NAME
perlstyle - Perl 风格指南

DESCRIPTION 描述
每个程序员当然都会有自己的编程风格，但是有一些一般性的原则可以使得我们的程序更易于阅读，理解，以及维护。

最重要的是使用 -w 选项. 如果必须关闭该选项，可以用 "no warnings" 或变量 $^W 来在一定的代码段中关闭它. 你还应该使用 "use strict" 除非你清楚不使用它的理由. "use sigtrap" 和 "use diagnostics" 也是非常有用的.

关于代码美学, Larry 大概只强烈的关心一件事情：多行块的结束花括号应该与开始的关键字对齐. 除了这个, 还有一些不是那么重要的事情:

•   4-列缩进.

•   如果可能的话，开始的花括号与关键词最好放在同一行，否则对齐.

•   多行的块的开始的花括号之前应当有空格

•   单行的块放在一行，包括花括号.

•   分号前不要空格.

•   在短的单行块中省略分号.

•   操作符周围打空格.

•   在“复合”下标周围打空格 (在括号中).

•   在不同功能的块之间打空行.

•   else另起一行写

•   函数与括号间不要空格

•   每个逗号后打空格.

•   长句子在操作符后截断 ( "and" 和 "or" 除外).

•   关闭括号后打空格.

•   相关项之间以列对齐.

•   在不影响清晰的情况下尽量减少标点符号.

Larry 这样做当然有他的原因, 不过他没有要求别人都和他一样.

以下意见供您参考:

•   可以那样做并不意味着应该那样做. Perl 设计为作每件事都可以用好几种方法, 你应该选择最可读的一种. 例如

        open(FOO,$foo) || die "Can't open $foo: $!";

    好于

        die "Can't open $foo: $!" unless open(FOO,$foo);

    因为第二种办法掩盖了句子中的主要内容。另一方面

        print "Starting analysis\n" if $verbose;

    好于

        $verbose && print "Starting analysis\n";

    因为主要关键不在于是否用户输入了 -v。

    类似的，因为一个操作符允许使用默认参数，不意味着你必须使用默认值。默认值是为懒惰的系统程序员书写只运行一次的程序准备的。如果你需要你的程序尽量可读，考虑给出参数。

    根据相同的原则，在很多地方即使你可以忽略括号也不意味着你应当这样做：

        return print reverse sort num values %array;
        return print(reverse(sort num (values(%array))));

    如果有疑义，使用括号。至少它使得可怜的笨蛋能在 vi 中使用 % 键来跳转

    甚至你没有疑义的时候，为那个将来维护你的代码的家伙的精神健康考虑一下吧，并且他有可能把括号放错地方。

•   在程序中使用 last 跳出，而不要在开始和结束时用奇怪的跳转退出循环。把它 "缩出" 几格以利于察看:

        LINE:
            for (;;) {
                statements;
              last LINE if $foo;
                next LINE if /^#/;
                statements;
            }

•   别害怕使用循环标记--它们用来增强可读性并且允许多层循环中断. 参见前例.

•   避免在空上下文中使用 grep() (或 map()) 或 `反引号` , 那样，你就丢弃了它们的返回值. 使用它们是为了得到返回值，否则，使用 foreach() 或是 system() 好了.

•   考虑移植的时候，某些特性可能不是在所有的机器上都能够得到支持, 这时可以用 eval来测试. 如果你知道提供特定功能的版本或是补丁, 你可以察看 $] (也就是 "English" 中的 $PERL_VERSION) 来确定当前的版本. "Config" 模块也会提供perl在安装时 Configure 程序测得的值.

•   使用明确的标识符，你要是想不起来标识符的意思，那就麻烦了。

•   短标识符如 $gotit 虽然没什么不好, 但是用下划线来分割单词可以增加可读性. 如 $var_names_like_this 好于 $VarNamesLikeThis,对不以英语为母语的人更是如此.同样，在使用 VAR_NAMES_LIKE_THIS 时也要遵循这个规则。

    包名称有时不遵守这个约定. Perl 为 "pragma" 保留小写的包名称，比如 integer 和 strict. 其他模块名称应该用大写字母开始，但是一般不用下划线来分隔，因为当使用模块名来作文件名时，这在某些系统会出现错误.

•   使用大小写可以区分变量的作用域。例如:

        $ALL_CAPS_HERE   常量 (小心！不要与 perl 变量冲突!)
        $Some_Caps_Here  包作用域 global/static
        $no_caps_here    函数作用域 my() 或 local() 变量

    函数和方法名多用小写. 如, $obj->as_string().

    用下划线开始的函数名或变量名，表示该函数或变量只能在定义它的包中使用.

•   如果你的正则表达式较复杂，用 "/x" 来增加注释行或空行以利于阅读. 当其中有很多斜杠或反斜杠时，不要用反斜杠来作正则表达式的定界符.

•   使用 "and" 和 "or" 操作符以减少使用括号, 尽量少用 && 和 ||. 调用子程序时尽量少用"&"和括号，可以把子程序当做函数或列表操作符来调用.

•   使用 here documents 代替大量的 print() 语句.

•   相关语句用列对齐方式来书写，特别是当一行放不下的时候.

        $IDX = $ST_MTIME;
        $IDX = $ST_ATIME       if $opt_u;
        $IDX = $ST_CTIME       if $opt_c;
        $IDX = $ST_SIZE        if $opt_s;

        mkdir $tmpdir, 0700 or die "can't mkdir $tmpdir: $!";
        chdir($tmpdir)      or die "can't chdir $tmpdir: $!";
        mkdir 'tmp',   0777 or die "can't mkdir $tmpdir/tmp: $!";

•   总是检测返回值. 错误信息被送往 STDERR, 包括出错的程序、失败的系统调用及参数、并且（非常重要的）包括标准错误信息. 这里是一个简单而完整的例子:

        opendir(D, $dir)     or die "can't opendir $dir: $!";

•   把翻译列表以列对齐方式排列:

        tr [abc]
           [xyz];

•   考虑可重用性. 请考虑使用模块或对象. 考虑使用 use strict 和 use warnings (或 -w) 使代码清晰明确. 考虑改变世界观。

•   要一致，要兼容。

•   要漂亮，要美观。

译者
redcandle <redcandle51@chinaren.com> 20010530

中文手册页翻译计划
http://cmpp.linuxforum.net

跋
本页面中文版由中文 man 手册页计划提供。
中文 man 手册页计划：https://github.com/man-pages-zh/manpages-zh