package Regexp::Common::URI::RFC2384;


use Regexp::Common qw /pattern clean no_defaults/;
use Regexp::Common::URI::RFC1738 qw /$unreserved_range $escape $hostport/;

use strict;
use warnings;

our $VERSION = '2024080801';


use Exporter ();
our @ISA = qw /Exporter/;


my %vars;

BEGIN {
    $vars {low}     = [qw /$achar_range $achar $achars $achar_more/];
    $vars {connect} = [qw /$enc_sasl $enc_user $enc_ext $enc_auth_type $auth
                           $user_auth $server/];
    $vars {parts}   = [qw /$pop_url/];
}

our @EXPORT      = qw /$host/;
our @EXPORT_OK   = map {@$_} values %vars;
our %EXPORT_TAGS = (%vars, ALL => [@EXPORT_OK]);

# RFC 2384, POP3.

# Lowlevel definitions.
our $achar_range       =  "$unreserved_range&=~";
our $achar             =  "(?:[$achar_range]|$escape)";
our $achars            =  "(?:(?:[$achar_range]+|$escape)*)";
our $achar_more        =  "(?:(?:[$achar_range]+|$escape)+)";
our $enc_sasl          =  $achar_more;
our $enc_user          =  $achar_more;
our $enc_ext           =  "(?:[+](?:APOP|$achar_more))";
our $enc_auth_type     =  "(?:$enc_sasl|$enc_ext)";
our $auth              =  "(?:;AUTH=(?:[*]|$enc_auth_type))";
our $user_auth         =  "(?:$enc_user$auth?)";
our $server            =  "(?:(?:$user_auth\@)?$hostport)";
our $pop_url           =  "(?:pop://$server)";


1;

__END__

=pod

=head1 NAME

Regexp::Common::URI::RFC2384 -- Definitions from RFC2384;

=head1 SYNOPSIS

    use Regexp::Common::URI::RFC2384 qw /:ALL/;

=head1 DESCRIPTION

This package exports definitions from RFC2384. It's intended
usage is for Regexp::Common::URI submodules only. Its interface
might change without notice.

=head1 REFERENCES

=over 4

=item B<[RFC 2384]>

Gellens, R.: I<POP URL scheme> August 1998.

=back

=head1 AUTHOR

Abigail S<(I<regexp-common@abigail.freedom.nl>)>.

=head1 BUGS AND IRRITATIONS

Bound to be plenty.

=head1 LICENSE and COPYRIGHT

This software is Copyright (c) 2001 - 2024, Damian Conway and Abigail.

This module is free software, and maybe used under any of the following
licenses:

 1) The Perl Artistic License.     See the file COPYRIGHT.AL.
 2) The Perl Artistic License 2.0. See the file COPYRIGHT.AL2.
 3) The BSD License.               See the file COPYRIGHT.BSD.
 4) The MIT License.               See the file COPYRIGHT.MIT.

=cut
