// Check that the various shortcuts are working.
goto: file://|DOC_PATH|/test_docs/index.html
// We first check that the search input isn't already focused.
assert-false: "input.search-input:focus"
press-key: "s"
assert: "input.search-input:focus"
press-key: "Escape"
assert-false: "input.search-input:focus"
// We now check for the help popup.
press-key: "?"
assert-css: ("#help", {"display": "flex"})
assert-false: "#help.hidden"
press-key: "Escape"
assert-css: ("#help.hidden", {"display": "none"})
// Check for the themes list.
assert-css: ("#theme-choices", {"display": "none"})
press-key: "t"
assert-css: ("#theme-choices", {"display": "block"})
press-key: "t"
// We ensure that 't' hides back the menu.
assert-css: ("#theme-choices", {"display": "none"})
press-key: "t"
assert-css: ("#theme-choices", {"display": "block"})
press-key: "Escape"
// We ensure that 'Escape' hides the menu too.
assert-css: ("#theme-choices", {"display": "none"})
