GAP (CTblLibXpls) - Chapter 6: Solvable Subgroups of Maximal Order in Sporadic Simple Groups

Goto Chapter: Top 1 2 3 4 5 6 7 8 9 10 11 Bib Ind
[Top of Book] [Contents] [Previous Chapter] [Next Chapter]

[MathJax off]

6 Solvable Subgroups of Maximal Order in Sporadic Simple Groups
6.1 The Result
6.2 The Approach
6.2-1 Use the Table of Marks
6.2-2 Use Information from the Character Table Library
6.3 Cases where the Table of Marks is available in GAP
6.4 Cases where the Table of Marks is not available in GAP
6.4-1 \(G = Ru\)
6.4-2 \(G = Suz\)
6.4-3 \(G = ON\)
6.4-4 \(G = Co_2\)
6.4-5 \(G = Fi_{22}\)
6.4-6 \(G = HN\)
6.4-7 \(G = Ly\)
6.4-8 \(G = Th\)
6.4-9 \(G = Fi_{23}\)
6.4-10 \(G = Co_1\)
6.4-11 \(G = J_4\)
6.4-12 \(G = Fi_{24}^{\prime}\)
6.4-13 \(G = B\)
6.4-14 \(G = M\)
6.5 Proof of the Corollary

### 6 Solvable Subgroups of Maximal Order in Sporadic Simple Groups

Date: May 14th, 2012

We determine the orders of solvable subgroups of maximal orders in sporadic simple groups and their automorphism groups, using the information in the Atlas of Finite Groups [CCN+85] and the GAP system [GAP21], in particular its Character Table Library [Bre24] and its library of Tables of Marks [MNP19].

We also determine the conjugacy classes of these solvable subgroups in the big group, and the maximal overgroups.

A first version of this document, which was based on GAP 4.4.10, had been accessible in the web since August 2006. The differences to the current version are as follows.

- The format of the GAP output was adjusted to the changed behaviour of GAP 4.5.

- The (too wide) table of results was split into two tables, the first one lists the orders and indices of the subgroups, the second one lists the structure of subgroups and the maximal overgroups.

- The distribution of the solvable subgroups of maximal orders in the Baby Monster group and the Monster group to conjugacy classes is now proved.

- The sporadic simple Monster group has exactly one class of maximal subgroups of the type PSL\((2, 41)\) (see [NW13]), and has no maximal subgroups which have the socle PSL\((2, 27)\) (see [Wil10]). This does not affect the arguments in Section 6.4-14, but some statements in this section had to be corrected.

#### 6.1 The Result

The tables I and II list information about solvable subgroups of maximal order in sporadic simple groups and their automorphism groups. The first column in each table gives the names of the almost simple groups \(G\), in alphabetical order. The remaining columns of Table I contain the order and the index of a solvable subgroup \(S\) of maximal order in \(G\), the value \(\log_{|G|}(|S|)\), and the page number in the Atlas [CCN+85] where the information about maximal subgroups of \(G\) is listed. The second and third columns of Table II show a structure description of \(S\) and the structures of the maximal subgroups that contain \(S\); the value "\(S\)" in the third column means that \(S\) is itself maximal in \(G\). The fourth and fifth columns list the pages in the Atlas with the information about the maximal subgroups of \(G\) and the section in this note with the proof of the table row, respectively. In the fourth column, page numbers in brackets refer to the Atlas pages with information about the maximal subgroups of nonsolvable quotients of the maximal subgroups of \(G\) listed in the third column.

Note that in the case of nonmaximal subgroups \(S\), we do not claim to describe the module structure of \(S\) in the third column of the table; we have kept the Atlas description of the normal subgroups of the maximal overgroups of \(S\). For example, the subgroup \(S\) listed for \(Co_2\) is contained in maximal subgroups of the types \(2^{1+8}_+:S_6(2)\) and \(2^{4+10}(S_4 \times S_3)\), so \(S\) has normal subgroups of the orders \(2\), \(2^4\), \(2^9\), \(2^{14}\), and \(2^{16}\); more Atlas conformal notations would be \(2^{[14]}(S_4 \times S_3)\) or \(2^{[16]}(S_3 \times S_3)\).

As a corollary (see Section 6.5), we read off the following.

Corollary:

Exactly the following almost simple groups \(G\) with sporadic simple socle contain a solvable subgroup \(S\) with the property \(|S|^2 \geq |G|\).

\[ Fi_{23}, J_2, J_2.2, M_{11}, M_{12}, M_{22}.2. \]

The existence of the subgroups \(S\) of \(G\) with the structure and the order stated in Table I and II follows from the Atlas: It is obvious in the cases where \(S\) is maximal in \(G\), and in the other cases, the Atlas information about a nonsolvable factor group of a maximal subgroup of \(G\) suffices.

In order to show that the table rows for the group \(G\) are correct, we have to show the following.

- \(G\) does not contain solvable subgroups of order larger than \(|S|\).

- \(G\) contain exactly the conjugacy classes of solvable subgroups of order \(|S|\) that are listed in the second column of Table II.

- \(S\) is contained exactly in the maximal subgroups listed in the third column of Table II.

Remark:

- Each of the groups \(M_{12}\) and \(He\) contains two classes of isomorphic solvable subgroups of maximal order.

- Each of the groups \(Ru\), \(Th\), and \(M\) contains two classes of nonisomorphic solvable subgroups of maximal order.

- The solvable subgroups of maximal order in \(McL.2\) have the structure \(3^{1+4}_+:4S_4\), the subgroups are maximal in the maximal subgroups of the structures \(3^{1+4}_+:4S_5\) and \(U_4(3).2_3\) in \(McL.2\). Note that the Atlas claims another structure for these maximal subgroups of \(U_4(3).2_3\), see [CCN+85, p. 52].

- The solvable subgroups of maximal order in \(Co_3\) are the normalizers of Sylow \(3\)-subgroups of \(Co_3\).

Table: Table I: Solvable subgroups of maximal order – orders and indices
\(G\) | \(|S|\) | \(|G/S|\) | \(\log_{|G|}(|S|)\) | p. |
\(M_{11}\) | \(144\) | \(55\) | \(0.5536\) | \(18\) |
\(M_{12}\) | \(432\) | \(220\) | \(0.5294\) | \(33\) |
\(M_{12}.2\) | \(432\) | \(440\) | \(0.4992\) | \(33\) |
\(J_1\) | \(168\) | \(1\,045\) | \(0.4243\) | \(36\) |
\(M_{22}\) | \(576\) | \(770\) | \(0.4888\) | \(39\) |
\(M_{22}.2\) | \(1\,152\) | \(770\) | \(0.5147\) | \(39\) |
\(J_2\) | \(1\,152\) | \(525\) | \(0.5295\) | \(42\) |
\(J_2.2\) | \(2\,304\) | \(525\) | \(0.5527\) | \(42\) |
\(M_{23}\) | \(1\,152\) | \(8\,855\) | \(0.4368\) | \(71\) |
\(HS\) | \(2\,000\) | \(22\,176\) | \(0.4316\) | \(80\) |
\(HS.2\) | \(4\,000\) | \(22\,176\) | \(0.4532\) | \(80\) |
\(J_3\) | \(1\,944\) | \(25\,840\) | \(0.4270\) | \(82\) |
\(J_3.2\) | \(3\,888\) | \(25\,840\) | \(0.4486\) | \(82\) |
\(M_{24}\) | \(13\,824\) | \(17\,710\) | \(0.4935\) | \(96\) |
\(McL\) | \(11\,664\) | \(77\,000\) | \(0.4542\) | \(100\) |
\(McL.2\) | \(23\,328\) | \(77\,000\) | \(0.4719\) | \(100\) |
\(He\) | \(13\,824\) | \(291\,550\) | \(0.4310\) | \(104\) |
\(He.2\) | \(18\,432\) | \(437\,325\) | \(0.4305\) | \(104\) |
\(Ru\) | \(49\,152\) | \(2\,968\,875\) | \(0.4202\) | \(126\) |
\(Suz\) | \(139\,968\) | \(3\,203\,200\) | \(0.4416\) | \(131\) |
\(Suz.2\) | \(279\,936\) | \(3\,203\,200\) | \(0.4557\) | \(131\) |
\(O'N\) | \(25\,920\) | \(17\,778\,376\) | \(0.3784\) | \(132\) |
\(O'N.2\) | \(51\,840\) | \(17\,778\,376\) | \(0.3940\) | \(132\) |
\(Co_3\) | \(69\,984\) | \(7\,084\,000\) | \(0.4142\) | \(134\) |
\(Co_2\) | \(2\,359\,296\) | \(17\,931\,375\) | \(0.4676\) | \(154\) |
\(Fi_{22}\) | \(5\,038\,848\) | \(12\,812\,800\) | \(0.4853\) | \(163\) |
\(Fi_{22}.2\) | \(10\,077\,696\) | \(12\,812\,800\) | \(0.4963\) | \(163\) |
\(HN\) | \(2\,000\,000\) | \(136\,515\,456\) | \(0.4364\) | \(166\) |
\(HN.2\) | \(4\,000\,000\) | \(136\,515\,456\) | \(0.4479\) | \(166\) |
\(Ly\) | \(900\,000\) | \(57\,516\,865\,560\) | \(0.3562\) | \(174\) |
\(Th\) | \(944\,784\) | \(96\,049\,408\,000\) | \(0.3523\) | \(177\) |
\(Fi_{23}\) | \(3\,265\,173\,504\) | \(1\,252\,451\,200\) | \(0.5111\) | \(177\) |
\(Co_1\) | \(84\,934\,656\) | \(48\,952\,653\,750\) | \(0.4258\) | \(183\) |
\(J_4\) | \(28\,311\,552\) | \(3\,065\,023\,459\,190\) | \(0.3737\) | \(190\) |
\(Fi_{24}'\) | \(29\,386\,561\,536\) | \(42\,713\,595\,724\,800\) | \(0.4343\) | \(207\) |
\(Fi_{24}'.2\) | \(58\,773\,123\,072\) | \(42\,713\,595\,724\,800\) | \(0.4413\) | \(207\) |
\(B\) | \(29\,686\,813\,949\,952\) | \(139\,953\,768\,303\,693\,093\,750\) | \(0.4007\) | \(217\) |
\(M\) | \(2\,849\,934\,139\,195\,392\) | \(283\,521\,437\,805\,098\,363\,752\) |  |  |
|  | \(344\,287\,234\,566\,406\,250\) | \(0.2866\) | \(234\) |

Table: Table II: Solvable subgroups of maximal order – structures and overgroups
\(G\) | \(S\) | Max. overgroups | [CCN+85] |  | see
\(M_{11}\) | \(3^2:Q_8.2\) | \(S\) | 18 |  | 6.3
\(M_{12}\) | \(3^2:2S_4\) | \(S\) | 33 |  | 6.3
| \(3^2:2S_4\) | \(S\) | 33 |  | 6.3
\(M_{12}.2\) | \(3^2:2S_4\) | \(M_{12}\) | 33 |  | 6.3
\(J_1\) | \(2^3:7:3\) | \(S\) | 36 |  | 6.3
\(M_{22}\) | \(2^4:3^2:4\) | \(2^4:A_6\) | 39 | (4) | 6.3
\(M_{22}.2\) | \(2^4:3^2:D_8\) | \(2^4:S_6\) | 39 | (4) | 6.3
\(J_2\) | \(2^{2+4}:(3 \times S_3)\) | \(S\) | 42 |  | 6.3
\(J_2.2\) | \(2^{2+4}:(S_3 \times S_3)\) | \(S\) | 42 |  | 6.3
\(M_{23}\) | \(2^4:(3 \times A_4):2\) | \(2^4:(3 \times A_5):2\), | 71 | (2) | 6.3
|  | \(2^4:A_7\) |  | (10) |
\(HS\) | \(5^{1+2}_+:8:2\) | \(U_3(5).2\) | 80 | (34) | 6.3
|  | \(U_3(5).2\) |  |  | 6.3
\(HS.2\) | \(5^{1+2}_+:[2^5]\) | \(S\) | 80 | (34) | 6.3
\(J_3\) | \(3^2.3^{1+2}_+:8\) | \(S\) | 82 |  | 6.3
\(J_3.2\) | \(3^2.3^{1+2}_+:QD_{16}\) | \(S\) | 82 |  | 6.3
\(M_{24}\) | \(2^6:3^{1+2}_+:D_8\) | \(2^6:3.S_6\) | 96 | (4) | 6.3
\(McL\) | \(3^{1+4}_+:2S_4\) | \(3^{1+4}_+:2S_5\), | 100 | (2) | 6.3
|  | \(U_4(3)\) |  | (52) | 6.3
\(McL.2\) | \(3^{1+4}_+:4S_4\) | \(3^{1+4}_+:4S_5\), | 100 | (2) | 6.3
|  | \(U_4(3).2_3\) |  | (52) | 6.3
\(He\) | \(2^6:3^{1+2}_+:D_8\) | \(2^6:3.S_6\) | 104 | (4) | 6.3
| \(2^6:3^{1+2}_+:D_8\) | \(2^6:3.S_6\) |  | (4) | 6.3
\(He.2\) | \(2^{4+4}.(S_3 \times S_3).2\) | \(S\) | 104 |  | 6.3
\(Ru\) | \(2.2^{4+6}:S_4\) | \(2^{3+8}:L_3(2)\), | 126 | (3) | 6.4-1
|  | \(2.2^{4+6}:S_5\) |  | (2) |
| \(2^{3+8}:S_4\) | \(2^{3+8}:L_3(2)\), |  | (3) | 6.4-1
\(Suz\) | \(3^{2+4}:2(A_4 \times 2^2).2\) | \(S\) | 131 |  | 6.4-2
\(Suz.2\) | \(3^{2+4}:2(S_4 \times D_8)\) | \(S\) | 131 |  | 6.4-2
\(O'N\) | \(3^4:2^{1+4}_-D_{10}\) | \(S\) | 132 |  | 6.4-3
\(O'N.2\) | \(3^4:2^{1+4}_-.(5:4)\) | \(S\) | 132 |  | 6.4-3
\(Co_3\) | \(3^{1+4}_+:4.3^2:D_8\) | \(3^{1+4}_+:4S_6\) | 134 | (4) | 6.3
|  | \(3^5:(2 \times M_{11})\) |  | (18) |
\(Co_2\) | \(2^{4+10}(S_4 \times S_3)\) | \(2^{1+8}_+:S_6(2)\), | 154 | (46) | 6.4-4
|  | \(2^{4+10}(S_5 \times S_3)\) |  | (2) |
\(Fi_{22}\) | \(3^{1+6}_+:2^{3+4}:3^2:2\) | \(S\) | 163 |  | 6.4-5
\(Fi_{22}.2\) | \(3^{1+6}_+:2^{3+4}:(S_3 \times S_3)\) | \(S\) | 163 |  | 6.4-5
\(HN\) | \(5^{1+4}_+:2^{1+4}_-.5.4\) | \(S\) | 166 |  | 6.4-6
\(HN.2\) | \(5^{1+4}_+:(4 Y 2^{1+4}_-.5.4)\) | \(S\) | 166 |  | 6.4-6
\(Ly\) | \(5^{1+4}_+:4.3^2:D_8\) | \(5^{1+4}_+:4S_6\) | 174 | (4) | 6.4-7
\(Th\) | \([3^9].2S_4\) | \(S\) | 177 |  | 6.4-8
| \(3^2.[3^7].2S_4\) | \(S\) |  |  |
\(Fi_{23}\) | \(3^{1+8}_+.2^{1+6}_-.3^{1+2}_+.2S_4\) | \(S\) | 177 |  | 6.4-9
\(Co_1\) | \(2^{4+12}.(S_3 \times 3^{1+2}_+:D_8)\) | \(2^{4+12}.(S_3 \times 3S_6)\) | 183 |  | 6.4-10

Table: Table II: Solvable subgroups of maximal order – structures and overgroups (continued)
\(G\) | \(S\) | Max. overgroups | [CCN+85] |  | see
\(J_4\) | \(2^{11}:2^6:3^{1+2}_+:D_8\) | \(2^{11}:M_{24}\), | 190 | (96) | 6.4-11
|  | \(2^{1+12}_+.3M_{22}:2\) |  | (39) |
\(Fi_{24}'\) | \(3^{1+10}_+:2^{1+6}_-:3^{1+2}_+:2S_4\) | \(3^{1+10}_+:U_5(2):2\) | 207 | (73) | 6.4-12
\(Fi_{24}'.2\) | \(3^{1+10}_+:(2 \times 2^{1+6}_-:3^{1+2}_+:2S_4)\) | \(3^{1+10}_+:(2 \times U_5(2):2)\) | 207 | (73) | 6.4-12
\(B\) | \(2^{2+10+20}(2^4:3^2:D_8 \times S_3)\) | \(2^{2+10+20}(M_{22}:2 \times S_3)\), | 217 | (39) | 6.4-13
|  | \(2^{9+16}S_8(2)\) |  | (123) |
\(M\) | \(2^{1+2+6+12+18}.(S_4 \times 3^{1+2}_+:D_8)\) | \(2^{[39]}.(L_3(2) \times 3S_6)\), | 234 | (3, 4) | 6.4-14
|  | \(2^{1+24}_+.Co_1\) |  | (183) |
| \(2^{2+1+6+12+18}.(S_4 \times 3^{1+2}_+:D_8)\) | \(2^{[39]}.(L_3(2) \times 3S_6)\), |  | (3, 4) | 6.4-14
|  | \(2^{2+11+22}.(M_{24} \times S_3)\) |  | (96) |

#### 6.2 The Approach

We combine the information in the Atlas [CCN+85] with explicit computations using the GAP system [GAP21], in particular its Character Table Library [Bre24] and its library of Tables of Marks [MNP19]. First we load these two packages.

    gap> LoadPackage( "CTblLib", "1.2", false );
    true
    gap> LoadPackage( "TomLib", false );
    true

The orders of solvable subgroups of maximal order will be collected in a global record `MaxSolv`.

    gap> MaxSolv:= rec();;

##### 6.2-1 Use the Table of Marks

If the GAP library of Tables of Marks [MNP19] contains the table of marks of a group \(G\) then we can easily inspect all conjugacy classes of subgroups of \(G\). The following small GAP function can be used for that. It returns `false` if the table of marks of the group with the name `name` is not available, and the list `[ name, n, super ]` otherwise, where `n` is the maximal order of solvable subgroups of \(G\), and `super` is a list of lists; for each conjugacy class of solvable subgroups \(S\) of order `n`, `super` contains the list of orders of representatives \(M\) of the classes of maximal subgroups of \(G\) such that \(M\) contains a conjugate of \(S\).

Note that a subgroup in the \(i\)-th class of a table of marks contains a subgroup in the \(j\)-th class if and only if the entry in the position \((i,j)\) of the table of marks is nonzero. For tables of marks objects in GAP, this is the case if and only if \(j\) is contained in the \(i\)-th row of the list that is stored as the value of the attribute `SubsTom` of the table of marks object; for this test, one need not unpack the matrix of marks.

    gap> MaximalSolvableSubgroupInfoFromTom:= function( name )
    >     local tom,          # table of marks for `name'
    >           n,            # maximal order of a solvable subgroup
    >           maxsubs,      # numbers of the classes of subgroups of order `n'
    >           orders,       # list of orders of the classes of subgroups
    >           i,            # loop over the classes of subgroups
    >           maxes,        # list of positions of the classes of max. subgroups
    >           subs,         # `SubsTom' value
    >           cont;         # list of list of positions of max. subgroups
    >
    >     tom:= TableOfMarks( name );
    >     if tom = fail then
    >       return false;
    >     fi;
    >     n:= 1;
    >     maxsubs:= [];
    >     orders:= OrdersTom( tom );
    >     for i in [ 1 .. Length( orders ) ] do
    >       if IsSolvableTom( tom, i ) then
    >         if orders[i] = n then
    >           Add( maxsubs, i );
    >         elif orders[i] > n then
    >           n:= orders[i];
    >           maxsubs:= [ i ];
    >         fi;
    >       fi;
    >     od;
    >     maxes:= MaximalSubgroupsTom( tom )[1];
    >     subs:= SubsTom( tom );
    >     cont:= List( maxsubs, j -> Filtered( maxes, i -> j in subs[i] ) );
    >
    >     return [ name, n, List( cont, l -> orders{ l } ) ];
    > end;;

##### 6.2-2 Use Information from the Character Table Library

The GAP Character Table Library contains the character tables of all maximal subgroups of sporadic simple groups, except for the Monster group. This information can be used as follows.

We start, for a sporadic simple group \(G\), with a known solvable subgroup of order \(n\), say, in \(G\). In order to show that \(G\) contains no solvable subgroup of larger order, it suffices to show that no maximal subgroup of \(G\) contains a larger solvable subgroup.

The point is that usually the orders of the maximal subgroups of \(G\) are not much larger than \(n\), and that a maximal subgroup \(M\) contains a solvable subgroup of order \(n\) only if the factor group of \(M\) by its largest solvable normal subgroup \(N\) contains a solvable subgroup of order \(n/|N|\). This reduces the question to relatively small groups.

What we can check automatically from the character table of \(M/N\) is whether \(M/N\) can contain subgroups (solvable or not) of indices between five and \(|M|/n\), by computing possible permutation characters of these degrees. (Note that a solvable subgroup of a nonsolvable group has index at least five. This lower bound could be improved for example by considering the smallest degree of a nontrivial character, but this is not an issue here.)

Then we are left with a –hopefully short– list of maximal subgroups of \(G\), together with upper bounds on the indices of possible solvable subgroups; excluding these possibilities then yields that the initially chosen solvable subgroup of \(G\) is indeed the largest one.

The following GAP function can be used to compute this information for the character table `tblM` of \(M\) and a given order `minorder`. It returns `false` if \(M\) cannot contain a solvable subgroup of order at least `minorder`, otherwise a list `[ tblM, m, k ]` where `m` is the maximal index of a subgroup that has order at least `minorder`, and `k` is the minimal index of a possible subgroup of \(M\) (a proper subgroup if \(M\) is nonsolvable), according to the GAP function `PermChars` (Reference: PermChars).

    gap> SolvableSubgroupInfoFromCharacterTable:= function( tblM, minorder )
    >     local maxindex,  # index of subgroups of order `minorder'
    >           N,         # class positions describing a solvable normal subgroup
    >           fact,      # character table of the factor by `N'
    >           classes,   # class sizes in `fact'
    >           nsg,       # list of class positions of normal subgroups
    >           i;         # loop over the possible indices
    >
    >     maxindex:= Int( Size( tblM ) / minorder );
    >     if   maxindex = 0 then
    >       return false;
    >     elif IsSolvableCharacterTable( tblM ) then
    >       return [ tblM, maxindex, 1 ];
    >     elif maxindex < 5 then
    >       return false;
    >     fi;
    >
    >     N:= [ 1 ];
    >     fact:= tblM;
    >     repeat
    >       fact:= fact / N;
    >       classes:= SizesConjugacyClasses( fact );
    >       nsg:= Difference( ClassPositionsOfNormalSubgroups( fact ), [ [ 1 ] ] );
    >       N:= First( nsg, x -> IsPrimePowerInt( Sum( classes{ x } ) ) );
    >     until N = fail;
    >
    >     for i in Filtered( DivisorsInt( Size( fact ) ),
    >                        d -> 5 <= d and d <= maxindex ) do
    >       if Length( PermChars( fact, rec( torso:= [ i ] ) ) ) > 0 then
    >         return [ tblM, maxindex, i ];
    >       fi;
    >     od;
    >
    >     return false;
    > end;;

#### 6.3 Cases where the Table of Marks is available in GAP

For twelve sporadic simple groups, the GAP library of Tables of Marks knows the tables of marks, so we can use `MaximalSolvableSubgroupInfoFromTom`.

    gap> solvinfo:= Filtered( List(
    >         AllCharacterTableNames( IsSporadicSimple, true,
    >                                 IsDuplicateTable, false ),
    >         MaximalSolvableSubgroupInfoFromTom ), x -> x <> false );;
    gap> for entry in solvinfo do
    >      MaxSolv.( entry[1] ):= entry[2];
    >    od;
    gap> for entry in solvinfo do
    >      Print( String( entry[1], 5 ), String( entry[2], 7 ),
    >             String( entry[3], 28 ), "\n" );
    >    od;
      Co3  69984     [ [ 3849120, 699840 ] ]
       HS   2000      [ [ 252000, 252000 ] ]
       He  13824  [ [ 138240 ], [ 138240 ] ]
       J1    168                 [ [ 168 ] ]
       J2   1152                [ [ 1152 ] ]
       J3   1944                [ [ 1944 ] ]
      M11    144                 [ [ 144 ] ]
      M12    432        [ [ 432 ], [ 432 ] ]
      M22    576                [ [ 5760 ] ]
      M23   1152         [ [ 40320, 5760 ] ]
      M24  13824              [ [ 138240 ] ]
      McL  11664      [ [ 3265920, 58320 ] ]

We see that for \(J_1\), \(J_2\), \(J_3\), \(M_{11}\), and \(M_{12}\), the subgroup \(S\) is maximal. For \(M_{12}\) and \(He\), there are two classes of subgroups \(S\). For the other groups, the class of subgroups \(S\) is unique, and there are one or two classes of maximal subgroups of \(G\) that contain \(S\). From the shown orders of these maximal subgroups, their structures can be read off from the Atlas, on the pages listed in Table II.

Similarly, the Atlas tells us about the extensions of the subgroups \(S\) in Aut\((G)\). In particular,

- the order \(2\,000\) subgroups of \(HS\) are contained in maximal subgroups of the type \(U_3(5).2\) (two classes) which do not extend to \(HS.2\), but there are novelties of the type \(5^{1+2}_+:[2^5]\) and of the order \(4\,000\), so the solvable subgroups of maximal order in \(HS\) do in fact extend to \(HS.2\).

- the order \(13\,824\) subgroups of \(He\) are contained in maximal subgroups of the type \(2^6:3S_6\) (two classes) which do not extend to \(He.2\), but there are novelties of the type \(2^{4+4}.(S_3 \times S_3).2\) and of the order \(18\,432\). (So the solvable subgroups \(S\) of maximal order in \(He\) do not extend to \(He.2\) but there are larger solvable subgroups in \(He.2\).)

  We inspect the maximal subgroups of \(He.2\) in order to show that these are in fact the solvable subgroups of maximal order (see [CCN+85, p. 104]): Any other solvable subgroup of order at least \(n\) in \(He.2\) must be contained in a subgroup of one of the types \(S_4(4).4\) (of index at most \(212\)), \(2^2.L_3(4).D_{12}\) (of index at most \(52\)), or \(2^{1+6}_+.L_3(2).2\) (of index at most \(2\)). By [CCN+85, pp. 44, 23, 3], this is not the case.

- the maximal subgroups of order \(1\,152\) in \(J_2\) extend to subgroups of order \(2\,304\) in \(J_2.2\).

- the maximal subgroups of order \(1\,944\) in \(J_3\) extend to subgroups of the type \(3^2.3^{1+2}_+:8.2\) and of order \(3888\) in \(J_3.2\). (The structure stated in [CCN+85, p. 82] is not correct, see [BN95].)

- the maximal subgroups of order \(432\) in \(M_{12}\) (two classes) do not extend in \(M_{12}.2\), and we see from the table of marks of \(M_{12}.2\) that there are no larger solvable subgroups in this group, i. e., the solvable subgroups of maximal order in \(M_{12}.2\) lie in \(M_{12}\).

- the order \(576\) subgroups of \(M_{22}\) are contained in maximal subgroups of the type \(2^4:A_6\) which extend to subgroups of the type \(2^4:S_6\) in \(M_{22}.2\), so the solvable subgroups of maximal order in \(M_{22}.2\) have the type \(2^4:3^2:D_8\) and the order \(1\,152\). In fact the structure is \(S_4 \wr S_2\).

- the order \(11\,664\) subgroups of \(McL\) are contained in maximal subgroups of the type \(3^{1+4}_+:2S_5\) which extend to subgroups of the type \(3^{1+4}:4S_5\) in \(McL.2\), so the solvable subgroups of maximal order in \(McL.2\) have the type \(3^{1+4}:4S_4\) and the order \(23\,328\).

    gap> MaxSolv.( "HS.2" ):= 2 * MaxSolv.( "HS" );;
    gap> n:= 2^(4+4) * ( 6 * 6 ) * 2;  MaxSolv.( "He.2" ):= n;;
    18432
    gap> List( [ Size( CharacterTable( "S4(4).4" ) ),
    >            Factorial( 5 )^2 * 2,
    >            Size( CharacterTable( "2^2.L3(4).D12" ) ),
    >            2^7 * Size( CharacterTable( "L3(2)" ) ) * 2,
    >            7^2 * 2 * Size( CharacterTable( "L2(7)" ) ) * 2,
    >            3 * Factorial( 7 ) * 2 ], i -> Int( i / n ) );
    [ 212, 1, 52, 2, 1, 1 ]
    gap> MaxSolv.( "J2.2" ):= 2 * MaxSolv.( "J2" );;
    gap> MaxSolv.( "J3.2" ):= 2 * MaxSolv.( "J3" );;
    gap> info:= MaximalSolvableSubgroupInfoFromTom( "M12.2" );
    [ "M12.2", 432, [ [ 95040 ] ] ]
    gap> MaxSolv.( "M12.2" ):= info[2];;
    gap> MaxSolv.( "M22.2" ):= 2 * MaxSolv.( "M22" );;
    gap> MaxSolv.( "McL.2" ):= 2 * MaxSolv.( "McL" );;

#### 6.4 Cases where the Table of Marks is not available in GAP

We use the GAP function `SolvableSubgroupInfoFromCharacterTable`, and individual arguments. In several cases, information about smaller sporadic simple groups is needed, so we deal with the groups in increasing order.

##### 6.4-1 \(G = Ru\)

The group \(Ru\) contains exactly two conjugacy classes of nonisomorphic solvable subgroups of order \(n = 49\,152\), and no larger solvable subgroups.

    gap> t:= CharacterTable( "Ru" );;
    gap> mx:= List( Maxes( t ), CharacterTable );;
    gap> n:= 49152;;
    gap> info:= List( mx, x -> SolvableSubgroupInfoFromCharacterTable( x, n ) );;
    gap> info:= Filtered( info, IsList );
    [ [ CharacterTable( "2^3+8:L3(2)" ), 7, 7 ],
      [ CharacterTable( "2.2^4+6:S5" ), 5, 5 ] ]

The maximal subgroups of the structure \(2.2^{4+6}:S_5\) in \(Ru\) contain one class of solvable subgroups of order \(n\) and with the structure \(2.2^{4+6}:S_4\), see [CCN+85, p. 126, p. 2].

The maximal subgroups of the structure \(2^{3+8}:L_3(2)\) in \(Ru\) contain two classes of solvable subgroups of order \(n\) and with the structure \(2^{3+8}:S_4\), see [CCN+85, p. 126, p. 3]. These groups are the stabilizers of vectors and two-dimensional subspaces, respectively, in the three-dimensional submodule; note that each \(2^{3+8}:L_3(2)\) type subgroup \(H\) of \(Ru\) is the normalizer of an elementary abelian group of order eight all of whose involutions are in the \(Ru\)-class `2A` and are conjugate in \(H\). Since the \(2.2^{4+6}:S_5\) type subgroups of \(Ru\) are the normalizers of `2A`-elements in \(Ru\), the groups in one of the two classes in question coincide with the largest solvable subgroups in the \(2.2^{4+6}:S_5\) type subgroups. The groups in the other class do not centralize a `2A`-element in \(Ru\) and are therefore not isomorphic with the \(2.2^{4+6}:S_4\) type groups.

    gap> MaxSolv.( "Ru" ):= n;;
    gap> s:= info[1][1];;
    gap> cls:= SizesConjugacyClasses( s );;
    gap> nsg:= Filtered( ClassPositionsOfNormalSubgroups( s ),
    >                    x -> Sum( cls{ x } ) = 2^3 );
    [ [ 1, 2 ] ]
    gap> cls{ nsg[1] };
    [ 1, 7 ]
    gap> GetFusionMap( s, t ){ nsg[1] };
    [ 1, 2 ]

##### 6.4-2 \(G = Suz\)

The group \(Suz\) contains a unique conjugacy class of solvable subgroups of order \(n = 139\,968\), and no larger solvable subgroups.

    gap> t:= CharacterTable( "Suz" );;
    gap> mx:= List( Maxes( t ), CharacterTable );;
    gap> n:= 139968;;
    gap> info:= List( mx, x -> SolvableSubgroupInfoFromCharacterTable( x, n ) );;
    gap> info:= Filtered( info, IsList );
    [ [ CharacterTable( "G2(4)" ), 1797, 416 ],
      [ CharacterTable( "3_2.U4(3).2_3'" ), 140, 72 ],
      [ CharacterTable( "3^5:M11" ), 13, 11 ],
      [ CharacterTable( "2^4+6:3a6" ), 7, 6 ],
      [ CharacterTable( "3^2+4:2(2^2xa4)2" ), 1, 1 ] ]

The maximal subgroups \(S\) of the structure \(3^{2+4}:2(A_4 \times 2^2).2\) in \(Suz\) are solvable and have order \(n\), see [CCN+85, p. 131].

In order to show that \(Suz\) contains no other solvable subgroups of order larger than or equal to \(|S|\), we check that there are no solvable subgroups in \(G_2(4)\) of index at most \(1\,797\) (see [CCN+85, p. 97]), in \(U_4(3).2_3^{\prime}\) of index at most \(140\) (see [CCN+85, p. 52]), in \(M_{11}\) of index at most \(13\) (see [CCN+85, p. 18]), and in \(A_6\) of index at most \(7\) (see [CCN+85, p. 4]).

The group \(S\) extends to a group of the structure \(3^{2+4}:2(S_4 \times D_8)\) in the automorphism group \(Suz.2\).

    gap> MaxSolv.( "Suz" ):= n;;
    gap> MaxSolv.( "Suz.2" ):= 2 * n;;

##### 6.4-3 \(G = ON\)

The group \(ON\) contains a unique conjugacy class of solvable subgroups of order \(25\,920\), and no larger solvable subgroups.

    gap> t:= CharacterTable( "ON" );;
    gap> mx:= List( Maxes( t ), CharacterTable );;
    gap> n:= 25920;;
    gap> info:= List( mx, x -> SolvableSubgroupInfoFromCharacterTable( x, n ) );;
    gap> info:= Filtered( info, IsList );
    [ [ CharacterTable( "L3(7).2" ), 144, 114 ],
      [ CharacterTable( "ONM2" ), 144, 114 ],
      [ CharacterTable( "3^4:2^(1+4)D10" ), 1, 1 ] ]

The maximal subgroups \(S\) of the structure \(3^4:2^{1+4}_-D_{10}\) in \(ON\) are solvable and have order \(n\), see [CCN+85, pp. 132].

In order to show that \(ON\) contains no other solvable subgroups of order larger than or equal to \(|S|\), we check that there are no solvable subgroups in \(L_3(7).2\) of index at most \(144\) (see [CCN+85, p. 50]); note that the groups in the second class of maximal subgroups of \(ON\) are isomorphic with \(L_3(7).2\).

The group \(S\) extends to a group of order \(|S.2|\) in the automorphism group \(ON.2\).

    gap> MaxSolv.( "ON" ):= n;;
    gap> MaxSolv.( "ON.2" ):= 2 * n;;

##### 6.4-4 \(G = Co_2\)

The group \(Co_2\) contains a unique conjugacy class of solvable subgroups of order \(2\,359\,296\), and no larger solvable subgroups.

    gap> t:= CharacterTable( "Co2" );;
    gap> mx:= List( Maxes( t ), CharacterTable );;
    gap> n:= 2359296;;
    gap> info:= List( mx, x -> SolvableSubgroupInfoFromCharacterTable( x, n ) );;
    gap> info:= Filtered( info, IsList );
    [ [ CharacterTable( "U6(2).2" ), 7796, 672 ],
      [ CharacterTable( "2^10:m22:2" ), 385, 22 ],
      [ CharacterTable( "McL" ), 380, 275 ],
      [ CharacterTable( "2^1+8:s6f2" ), 315, 28 ],
      [ CharacterTable( "2^1+4+6.a8" ), 17, 8 ],
      [ CharacterTable( "U4(3).D8" ), 11, 8 ],
      [ CharacterTable( "2^(4+10)(S5xS3)" ), 5, 5 ] ]

The maximal subgroups of the structure \(2^{4+10}(S_5 \times S_3)\) in \(Co_2\) contain solvable subgroups \(S\) of order \(n\) and with the structure \(2^{4+10}(S_4 \times S_3)\), see [CCN+85, p. 154].

The subgroups \(S\) are contained also in the maximal subgroups of the type \(2^{1+8}_+:S_6(2)\); note that the \(2^{1+8}_+:S_6(2)\) type subgroups are described as normalizers of elements in the \(Co_2\)-class `2A`, and \(S\) normalizes an elementary abelian group of order \(16\) containing an \(S\)-class of length five that is contained in the \(Co_2\)-class `2A`.

    gap> s:= info[7][1];
    CharacterTable( "2^(4+10)(S5xS3)" )
    gap> cls:= SizesConjugacyClasses( s );;
    gap> nsg:= Filtered( ClassPositionsOfNormalSubgroups( s ),
    >                    x -> Sum( cls{ x } ) = 2^4 );
    [ [ 1 .. 3 ] ]
    gap> cls{ nsg[1] };
    [ 1, 5, 10 ]
    gap> GetFusionMap( s, t ){ nsg[1] };
    [ 1, 2, 3 ]

The stabilizers of these involutions in \(2^{4+10}(S_5 \times S_3)\) have index five, they are solvable, and they are contained in \(2^{1+8}_+:S_6(2)\) type subgroups, so they are \(Co_2\)-conjugates of \(S\). (The corresponding subgroups of \(S_6(2)\) are maximal and have the type \(2.[2^6]:(S_3 \times S_3)\).)

In order to show that \(G\) contains no other solvable subgroups of order larger than or equal to \(|S|\), we check that there are no solvable subgroups in \(U_6(2)\) of index at most \(7\,796\) (see [CCN+85, p. 115]), in \(M_{22}.2\) of index at most \(385\) (see [CCN+85, p. 39] or Section 6.3), in \(McL\) of index at most \(380\) (see [CCN+85, p. 100] or Section 6.3), in \(A_8\) of index at most \(17\) (see [CCN+85, p. 20]), and in \(U_4(3).D_8\) of index at most \(11\) (see [CCN+85, p. 52]).

    gap> MaxSolv.( "Co2" ):= n;;

##### 6.4-5 \(G = Fi_{22}\)

The group \(Fi_{22}\) contains a unique conjugacy class of solvable subgroups of order \(5\,038\,848\), and no larger solvable subgroups.

    gap> t:= CharacterTable( "Fi22" );;
    gap> mx:= List( Maxes( t ), CharacterTable );;
    gap> n:= 5038848;;
    gap> info:= List( mx, x -> SolvableSubgroupInfoFromCharacterTable( x, n ) );;
    gap> info:= Filtered( info, IsList );
    [ [ CharacterTable( "2.U6(2)" ), 3650, 672 ],
      [ CharacterTable( "O7(3)" ), 910, 351 ],
      [ CharacterTable( "Fi22M3" ), 910, 351 ],
      [ CharacterTable( "O8+(2).3.2" ), 207, 6 ],
      [ CharacterTable( "2^10:m22" ), 90, 22 ],
      [ CharacterTable( "3^(1+6):2^(3+4):3^2:2" ), 1, 1 ] ]

The maximal subgroups \(S\) of the structure \(3^{1+6}:2^{3+4}:3^2:2\) in \(Fi_{22}\) are solvable and have order \(n\), see [CCN+85, p. 163].

In order to show that \(Fi_{22}\) contains no other solvable subgroups of order larger than or equal to \(|S|\), we check that there are no solvable subgroups in \(U_6(2)\) of index at most \(3\,650\) (see [CCN+85, p. 115]), in \(O_7(3)\) of index at most \(910\) (see [CCN+85, p. 109]), in \(O_8^+(2).S_3\) of index at most \(207\) (see [CCN+85, p. 85]), and in \(M_{22}.2\) of index at most \(90\) (see [CCN+85, p. 39] or Section 6.3); note that the groups in the third class of maximal subgroups of \(Fi_{22}\) are isomorphic with \(O_7(3)\).

The group \(S\) extends to a group of order \(|S.2|\) in the automorphism group \(Fi_{22}.2\).

    gap> MaxSolv.( "Fi22" ):= n;;
    gap> MaxSolv.( "Fi22.2" ):= 2 * n;;

##### 6.4-6 \(G = HN\)

The group \(HN\) contains a unique conjugacy class of solvable subgroups of order \(2\,000\,000\), and no larger solvable subgroups.

    gap> t:= CharacterTable( "HN" );;
    gap> mx:= List( Maxes( t ), CharacterTable );;
    gap> n:= 2000000;;
    gap> info:= List( mx, x -> SolvableSubgroupInfoFromCharacterTable( x, n ) );;
    gap> info:= Filtered( info, IsList );
    [ [ CharacterTable( "A12" ), 119, 12 ],
      [ CharacterTable( "5^(1+4):2^(1+4).5.4" ), 1, 1 ] ]

The maximal subgroups \(S\) of the structure \(5^{1+4}:2^{1+4}.5.4\) in \(HN\) are solvable and have order \(n\), see [CCN+85, p. 166].

In order to show that \(HN\) contains no other solvable subgroups of order larger than or equal to \(|S|\), we check that there are no solvable subgroups in \(A_{12}\) of index at most \(119\) (see [CCN+85, p. 91]).

The group \(S\) extends to a group of order \(|S.2|\) in the automorphism group \(HN.2\).

    gap> MaxSolv.( "HN" ):= n;;
    gap> MaxSolv.( "HN.2" ):= 2 * n;;

##### 6.4-7 \(G = Ly\)

The group \(Ly\) contains a unique conjugacy class of solvable subgroups of order \(900\,000\), and no larger solvable subgroups.

    gap> t:= CharacterTable( "Ly" );;
    gap> mx:= List( Maxes( t ), CharacterTable );;
    gap> n:= 900000;;
    gap> info:= List( mx, x -> SolvableSubgroupInfoFromCharacterTable( x, n ) );;
    gap> info:= Filtered( info, IsList );
    [ [ CharacterTable( "G2(5)" ), 6510, 3906 ],
      [ CharacterTable( "3.McL.2" ), 5987, 275 ],
      [ CharacterTable( "5^3.psl(3,5)" ), 51, 31 ],
      [ CharacterTable( "2.A11" ), 44, 11 ],
      [ CharacterTable( "5^(1+4):4S6" ), 10, 6 ] ]

The maximal subgroups of the structure \(5^(1+4):4S6\) in \(Ly\) contain solvable subgroups \(S\) of order \(n\) and with the structure \(5^{1+4}:4.3^2.D_8\), see [CCN+85, p. 174].

In order to show that \(Ly\) contains no other solvable subgroups of order larger than or equal to \(|S|\), we check that there are no solvable subgroups in \(G_2(5)\) of index at most \(6\,510\) (see [CCN+85, p. 114]), in \(McL.2\) of index at most \(5\,987\) (see [CCN+85, p. 100] or Section 6.3), in \(L_3(5)\) of index at most \(51\) (see [CCN+85, p. 38]), and in \(A_{11}\) of index at most \(44\) (see [CCN+85, p. 75]).

    gap> MaxSolv.( "Ly" ):= n;;

##### 6.4-8 \(G = Th\)

The group \(Th\) contains exactly two conjugacy classes of nonisomorphic solvable subgroups of order \(n = 944\,784\), and no larger solvable subgroups.

    gap> t:= CharacterTable( "Th" );;
    gap> mx:= List( Maxes( t ), CharacterTable );;
    gap> n:= 944784;;
    gap> info:= List( mx, x -> SolvableSubgroupInfoFromCharacterTable( x, n ) );;
    gap> info:= Filtered( info, IsList );
    [ [ CharacterTable( "2^5.psl(5,2)" ), 338, 31 ],
      [ CharacterTable( "2^1+8.a9" ), 98, 9 ],
      [ CharacterTable( "U3(8).6" ), 35, 6 ],
      [ CharacterTable( "ThN3B" ), 1, 1 ],
      [ CharacterTable( "ThM7" ), 1, 1 ] ]

The maximal subgroups \(S\) of the structures \([3^9].2S_4\) and \(3^2.[3^7].2S_4\) in \(Th\) are solvable and have order \(n\), see [CCN+85, p. 177].

In order to show that \(Th\) contains no other solvable subgroups of order larger than or equal to \(|S|\), we check that there are no solvable subgroups in \(L_5(2)\) of index at most \(338\) (see [CCN+85, p. 70]), in \(A_9\) of index at most \(98\) (see [CCN+85, p. 37]), and in \(U_3(8).6\) of index at most \(35\) (see [CCN+85, p. 66]).

    gap> MaxSolv.( "Th" ):= n;;

##### 6.4-9 \(G = Fi_{23}\)

The group \(Fi_{23}\) contains a unique conjugacy class of solvable subgroups of order \(n = 3\,265\,173\,504\), and no larger solvable subgroups.

    gap> t:= CharacterTable( "Fi23" );;
    gap> mx:= List( Maxes( t ), CharacterTable );;
    gap> n:= 3265173504;;
    gap> info:= List( mx, x -> SolvableSubgroupInfoFromCharacterTable( x, n ) );;
    gap> info:= Filtered( info, IsList );
    [ [ CharacterTable( "2.Fi22" ), 39545, 3510 ],
      [ CharacterTable( "O8+(3).3.2" ), 9100, 6 ],
      [ CharacterTable( "3^(1+8).2^(1+6).3^(1+2).2S4" ), 1, 1 ] ]

The maximal subgroups \(S\) of the structure \(3^{1+8}_+.2^{1+6}_-.3^{1+2}_+.2S_4\) in \(Fi_{23}\) are solvable and have order \(n\), see [CCN+85, p. 177].

In order to show that \(Fi_{23}\) contains no other solvable subgroups of order larger than or equal to \(|S|\), we check that there are no solvable subgroups in \(Fi_{22}\) of index at most \(39\,545\) (see Section 6.4-5) and in \(O_8^+(3).S_3\) of index at most \(9\,100\) (see [CCN+85, p. 140]).

    gap> MaxSolv.( "Fi23" ):= n;;

##### 6.4-10 \(G = Co_1\)

The group \(Co_1\) contains a unique conjugacy class of solvable subgroups of order \(n = 84\,934\,656\), and no larger solvable subgroups.

    gap> t:= CharacterTable( "Co1" );;
    gap> mx:= List( Maxes( t ), CharacterTable );;
    gap> n:= 84934656;;
    gap> info:= List( mx, x -> SolvableSubgroupInfoFromCharacterTable( x, n ) );;
    gap> info:= Filtered( info, IsList );
    [ [ CharacterTable( "Co2" ), 498093, 2300 ],
      [ CharacterTable( "3.Suz.2" ), 31672, 1782 ],
      [ CharacterTable( "2^11:M24" ), 5903, 24 ],
      [ CharacterTable( "Co3" ), 5837, 276 ],
      [ CharacterTable( "2^(1+8)+.O8+(2)" ), 1050, 120 ],
      [ CharacterTable( "U6(2).3.2" ), 649, 6 ],
      [ CharacterTable( "2^(2+12):(A8xS3)" ), 23, 8 ],
      [ CharacterTable( "2^(4+12).(S3x3S6)" ), 10, 6 ] ]

The maximal subgroups of the structure \(2^{4+12}.(S_3 \times 3S_6)\) in \(Co_1\) contain solvable subgroups \(S\) of order \(n\) and with the structure \(2^{4+12}.(S_3 \times 3^{1+2}_+:D_8)\), see [CCN+85, p. 183].

In order to show that \(Co_1\) contains no other solvable subgroups of order larger than or equal to \(|S|\), we check that there are no solvable subgroups in \(Co_2\) of index at most \(498\,093\) (see Section 6.4-4), in \(Suz.2\) of index at most \(31\,672\) (see Section 6.4-2), in \(M_{24}\) of index at most \(5\,903\) (see Section 6.3), in \(Co_3\) of index at most \(5\,837\) (see [CCN+85, p. 134] or Section 6.3), in \(O_8^+(2)\) of index at most \(1\,050\) (see [CCN+85, p. 185]), in \(U_6(2).S_3\) of index at most \(649\) (see [CCN+85, p. 115]), and in \(A_8\) of index at most \(23\) (see [CCN+85, p. 22]).

    gap> MaxSolv.( "Co1" ):= n;;

##### 6.4-11 \(G = J_4\)

The group \(J_4\) contains a unique conjugacy class of solvable subgroups of order \(28\,311\,552\), and no larger solvable subgroups.

    gap> t:= CharacterTable( "J4" );;
    gap> mx:= List( Maxes( t ), CharacterTable );;
    gap> n:= 28311552;;
    gap> info:= List( mx, x -> SolvableSubgroupInfoFromCharacterTable( x, n ) );;
    gap> info:= Filtered( info, IsList );
    [ [ CharacterTable( "mx1j4" ), 17710, 24 ],
      [ CharacterTable( "c2aj4" ), 770, 22 ],
      [ CharacterTable( "2^10:L5(2)" ), 361, 31 ],
      [ CharacterTable( "J4M4" ), 23, 5 ] ]

The maximal subgroups of the structure \(2^{11}:M_{24}\) in \(J_4\) contain solvable subgroups \(S\) of order \(n\) and with the structure \(2^{11}:2^6:3^{1+2}_+:D_8\), see Section 6.3 and [CCN+85, p. 190].

(The subgroups in the first four classes of maximal subgroups of \(J_4\) have the structures \(2^{11}:M_{24}\), \(2^{1+12}_+.3M_{22}:2\), \(2^{10}:L_5(2)\), and \(2^{3+12}.(S_5 \times L_3(2))\), in this order.)

The subgroups \(S\) are contained also in the maximal subgroups of the type \(2^{1+12}_+.3M_{22}:2\); note that these subgroups are described as normalizers of elements in the \(J_4\)-class `2A`, and \(S\) normalizes an elementary abelian group of order \(2^{11}\) containing an \(S\)-class of length \(1\,771\) that is contained in the \(J_4\)-class `2A`.

    gap> s:= info[1][1];
    CharacterTable( "mx1j4" )
    gap> cls:= SizesConjugacyClasses( s );;
    gap> nsg:= Filtered( ClassPositionsOfNormalSubgroups( s ),
    >                    x -> Sum( cls{ x } ) = 2^11 );
    [ [ 1 .. 3 ] ]
    gap> cls{ nsg[1] };
    [ 1, 276, 1771 ]
    gap> GetFusionMap( s, t ){ nsg[1] };
    [ 1, 3, 2 ]

The stabilizers of these involutions in \(2^{11}:M_{24}\) have index \(1\,771\), they have the structure \(2^{11}:2^6:3.S_6\), and they are contained in \(2^{1+12}_+.3M_{22}:2\) type subgroups; so also \(S\), which has index \(10\) in \(2^{11}:2^6:3.S_6\), is contained in \(2^{1+12}_+.3M_{22}:2\). (The corresponding subgroups of \(M_{22}:2\) are of course the solvable groups of maximal order described in Section 6.3.)

In order to show that \(G\) contains no other solvable subgroups of order larger than or equal to \(|S|\), we check that there are no solvable subgroups in \(L_5(2)\) of index at most \(361\) (see [CCN+85, p. 70]) and in \(S_5 \times L_3(2)\) of index at most \(23\) (see [CCN+85, pp. 2, 3]).

    gap> MaxSolv.( "J4" ):= n;;

##### 6.4-12 \(G = Fi_{24}^{\prime}\)

The group \(Fi_{24}^{\prime}\) contains a unique conjugacy class of solvable subgroups of order \(29\,386\,561\,536\), and no larger solvable subgroups.

    gap> t:= CharacterTable( "Fi24'" );;
    gap> mx:= List( Maxes( t ), CharacterTable );;
    gap> n:= 29386561536;;
    gap> info:= List( mx, x -> SolvableSubgroupInfoFromCharacterTable( x, n ) );;
    gap> info:= Filtered( info, IsList );
    [ [ CharacterTable( "Fi23" ), 139161244, 31671 ],
      [ CharacterTable( "2.Fi22.2" ), 8787, 3510 ],
      [ CharacterTable( "(3xO8+(3):3):2" ), 3033, 6 ],
      [ CharacterTable( "O10-(2)" ), 851, 495 ],
      [ CharacterTable( "3^(1+10):U5(2):2" ), 165, 165 ],
      [ CharacterTable( "2^2.U6(2).3.2" ), 7, 6 ] ]

The maximal subgroups of the structure \(3^{1+10}_+:U5(2):2\) in \(Fi_{24}^{\prime}\) contain solvable subgroups \(S\) of order \(n\) and with the structure \(3^{1+10}_+:2^{1+6}_-:3^{1+2}_+:2S_4\), see [CCN+85, p. 73, p. 207].

In order to show that \(G\) contains no other solvable subgroups of order larger than or equal to \(|S|\), we check that there are no solvable subgroups in \(Fi_{23}\) of order at least \(n\) (see Section 6.4-9), in \(Fi_{22}.2\) of order at least \(n\) (see Section 6.4-5), in \(O_8^+(3).S_3\) of index at most \(3\,033\) (see [CCN+85, p. 140]), in \(O_{10}^-(2)\) of index at most \(851\) (see [CCN+85, p. 147]), and in \(U_6(2).S_3\) of index at most \(7\) (see [CCN+85, p. 115]).

The group \(S\) extends to a group of order \(|S.2|\) in the automorphism group \(Fi_{24}\).

    gap> MaxSolv.( "Fi24'" ):= n;;
    gap> MaxSolv.( "Fi24'.2" ):= 2 * n;;

##### 6.4-13 \(G = B\)

The group \(B\) contains a unique conjugacy class of solvable subgroups of order \(n = 29\,686\,813\,949\,952\), and no larger solvable subgroups.

The maximal subgroups of the structure \(2^{2+10+20}(M_{22}:2 \times S_3)\) in \(B\) contain solvable subgroups \(S\) of order \(n\) and with the structure \(2^{2+10+20}(2^4:3^2:D_8 \times S_3)\), see [CCN+85, p. 217] and Section 6.3.

    gap> n:= 29686813949952;;
    gap> n = 2^(2+10+20) * 2^4 * 3^2 * 8 * 6;
    true
    gap> n = 2^(2+10+20) * MaxSolv.( "M22.2" ) * 6;
    true

By [Wil99, Table 1], the only maximal subgroups of \(B\) of order bigger than \(|S|\) have the following structures.

\(2.{}^2E_6(2).2\) | \(2^{1+22}.Co_2\) | \(Fi_{23}\) | \(2^{9+16}S_8(2)\)
\(Th\) | \((2^2 \times F_4(2)):2\) | \(2^{2+10+20}(M_{22}:2 \times S_3)\) | \(2^{5+5+10+10}L_5(2)\)
\(S_3 \times Fi_{22}:2\) | \(2^{[35]}(S_5 \times L_3(2))\) | \(HN:2\) | \(O_8^+(3):S_4\)

(The character tables of the maximal subgroups of \(B\) are meanwhile available in GAP.)

    gap> b:= CharacterTable( "B" );;
    gap> mx:= List( Maxes( b ), CharacterTable );;
    gap> Filtered( mx, x -> Size( x ) >= n );
    [ CharacterTable( "2.2E6(2).2" ), CharacterTable( "2^(1+22).Co2" ),
      CharacterTable( "Fi23" ), CharacterTable( "2^(9+16).S8(2)" ),
      CharacterTable( "Th" ), CharacterTable( "(2^2xF4(2)):2" ),
      CharacterTable( "2^(2+10+20).(M22.2xS3)" ),
      CharacterTable( "[2^30].L5(2)" ), CharacterTable( "S3xFi22.2" ),
      CharacterTable( "[2^35].(S5xL3(2))" ), CharacterTable( "HN.2" ),
      CharacterTable( "O8+(3).S4" ) ]

For the subgroups \(2^{1+22}.Co_2\), \(Fi_{23}\), \(Th\), \(S_3 \times Fi_{22}:2\), and \(HN:2\), the solvable subgroups of maximal order are known from the previous sections or can be derived from known values, and are smaller than \(n\).

    gap> List( [ 2^(1+22) * MaxSolv.( "Co2" ),
    >            MaxSolv.( "Fi23" ),
    >            MaxSolv.( "Th" ),
    >            6 * MaxSolv.( "Fi22.2" ),
    >            MaxSolv.( "HN.2" ) ], i -> Int( i / n ) );
    [ 0, 0, 0, 0, 0 ]

If one of the remaining maximal groups \(U\) from the above list has a solvable subgroup of order at least \(n\) then the index of this subgroup in \(U\) is bounded as follows.

    gap> List( [ Size( CharacterTable( "2.2E6(2).2" ) ),
    >            2^(9+16) * Size( CharacterTable( "S8(2)" ) ),
    >            2^3 * Size( CharacterTable( "F4(2)" ) ),
    >            2^(2+10+20) * Size( CharacterTable( "M22.2" ) ) * 6,
    >            2^30 * Size( CharacterTable( "L5(2)" ) ),
    >            2^35 * Factorial(5) * Size( CharacterTable( "L3(2)" ) ),
    >            Size( CharacterTable( "O8+(3)" ) ) * 24 ],
    >          i -> Int( i / n ) );
    [ 10311982931, 53550, 892, 770, 361, 23, 4 ]

The group \(O_8^+(3):S_4\) is nonsolvable, and its order is less than \(5 n\), thus its solvable subgroups have orders less than \(n\).

The largest solvable subgroup of \(S_5 \times L_3(2)\) has index \(35\), thus the solvable subgroups of \(2^{[35]}(S_5 \times L_3(2))\) have orders less than \(n\).

The groups of type \(2^{5+5+10+10}L_5(2)\) cannot contain solvable subgroups of order at least \(n\) because \(L_5(2)\) has no solvable subgroup of index up to \(361\) –such a subgroup would be contained in \(2^4:L_4(2)\), of index at most \(\lfloor 361/31 \rfloor = 11\) (see [CCN+85, p. 70]), and \(L_4(2) \cong A_8\) does not have such subgroups (see [CCN+85, p. 22]).

The largest proper subgroup of \(F_4(2)\) has index \(69\,615\) (see [CCN+85, p. 170]), which excludes solvable subgroups of order at least \(n\) in \((2^2 \times F_4(2)):2\).

Ruling out the group \(2.{}^2E_6(2).2\) is more involved. We consider the list of maximal subgroups of \({}^2E_6(2)\) in [CCN+85, p. 191] (which is complete, see [BN95]), and compute the maximal index of a group of order \(n/4\); the possible subgroups of \({}^2E_6(2)\) to consider are the following

\(2^{1+20}:U_6(2)\) | \(2^{8+16}:O_8^-(2)\) | \(F_4(2)\) | \(2^2.2^9.2^{18}:(L_3(4) \times S_3)\)
\(Fi_{22}\) | \(O_{10}^-(2)\) | \(2^3.2^{12}.2^{15}:(S_5 \times L_3(2))\) |

(The order of \(S_3 \times U_6(2)\) is already smaller than \(n/4\).)

    gap> List( [ 2^(1+20) * Size( CharacterTable( "U6(2)" ) ),
    >            2^(8+16) * Size( CharacterTable( "O8-(2)" ) ),
    >            Size( CharacterTable( "F4(2)" ) ),
    >            2^(2+9+18) * Size( CharacterTable( "L3(4)" ) ) * 6,
    >            Size( CharacterTable( "Fi22" ) ),
    >            Size( CharacterTable( "O10-(2)" ) ),
    >            2^(3+12+15) * 120 * Size( CharacterTable( "L3(2)" ) ),
    >            6 * Size( CharacterTable( "U6(2)" ) ) ],
    >          i -> Int( i / ( n / 4 ) ) );
    [ 2598, 446, 446, 8, 8, 3, 2, 0 ]

The indices of the solvable groups of maximal orders in the groups \(U_6(2)\), \(O_8^-(2)\), \(F_4(2)\), \(L_3(4)\), and \(Fi_{22}\) are larger than the bounds we get for \(n\), see [CCN+85, pp. 115, 89, 170, 23, 163].

It remains to consider the subgroups of the type \(2^{9+16}S_8(2)\). The group \(S_8(2)\) contains maximal subgroups of the type \(2^{3+8}:(S_3 \times S_6)\) and of index \(5\,355\) (see [CCN+85, p. 123]), which contain solvable subgroups \(S'\) of index \(10\). This yields solvable subgroups of order \(2^{9+16+3+8} \cdot 6 \cdot 72 = n\).

    gap> 2^(9+16+3+8) * 6 * 72 = n;
    true

There are no other solvable subgroups of larger or equal order in \(S_8(2)\): We would need solvable subgroups of index at most \(446\) in \(O_8^-(2):2\), \(393\) in \(O_8^+(2):2\), \(210\) in \(S_6(2)\), or \(23\) in \(A_8\), which is not the case by [CCN+85, pp. 89, 85, 46, 22].

    gap> index:= Int( 2^(9+16) * Size( CharacterTable( "S8(2)" ) ) / n );
    53550
    gap> List( [ 120, 136, 255, 2295 ], i -> Int( index / i ) );
    [ 446, 393, 210, 23 ]
    gap> MaxSolv.( "B" ):= n;;

So the \(2^{9+16}S_8(2)\) type subgroups of \(B\) yield solvable subgroups \(S'\) of the type \(2^{9+16}.2^{3+8}:(S_3 \times 3^2:D_8)\), and of order \(n\).

We want to show that \(S'\) is a \(B\)-conjugate of \(S\). For that, we first show the following:

Lemma:

The group \(B\) contains exactly two conjugacy classes of Klein four groups whose involutions lie in the class `2B`. (We will call these Klein four groups `2B`-pure.) Their normalizers in \(B\) have the orders \(22\,858\,846\,741\,463\,040\) and \(292\,229\,574\,819\,840\), respectively.

Proof. Let \(V\) be a `2B`-pure Klein four group in \(B\), and set \(N = N_B(V)\). Let \(x \in V\) be an involution and set \(H = C_B(x)\), then \(H\) is maximal in \(B\) and has the structure \(2^{1+22}.Co_2\). The index of \(C = C_B(V) = C_H(V)\) in \(N\) divides \(6\), and \(C\) stabilizes the central involution in \(H\) and another `2B` involution. The group \(H\) contains exactly four conjugacy classes of `2B` elements.

    gap> h:= mx[2];
    CharacterTable( "2^(1+22).Co2" )
    gap> pos:= Positions( GetFusionMap( h, b ), 3 );
    [ 2, 4, 11, 20 ]

The \(B\)-classes of `2B`-pure Klein four groups arise from those of these classes \(y^H \subset H\) such that \(x \neq y\) holds and \(x y\) is a `2B` element. We compute this subset.

    gap> pos:= Filtered( Difference( pos, [ 2 ] ), i -> ForAny( pos,
    >             j -> NrPolyhedralSubgroups( h, 2, i, j ).number <> 0 ) );
    [ 4, 11 ]

The two classes have lengths \(93\,150\) and \(7\,286\,400\), thus the index of \(C\) in \(H\) is one of these numbers.

    gap> SizesConjugacyClasses( h ){ pos };
    [ 93150, 7286400 ]

Next we compute the number \(n_0\) of `2B`-pure Klein four groups in \(B\).

    gap> nr:= NrPolyhedralSubgroups( b, 3, 3, 3 );
    rec( number := 14399283809600746875, type := "V4" )
    gap> n0:= nr.number;;

The \(B\)-conjugacy class of \(V\) has length \([B:N] = [B:H] \cdot [H:C] / [N:C]\), where \([N:C]\) divides \(6\). We see that \([N:C] = 6\) in both cases.

    gap> cand:= List( pos, i -> Size( b ) / SizesCentralizers( h )[i] / 6 );
    [ 181758140654146875, 14217525668946600000 ]
    gap> Sum( cand ) = n0;
    true

The orders of the normalizers of the two classes of `2B`-pure Klein four groups are as claimed.

    gap> List( cand, x -> Size( b ) / x );
    [ 22858846741463040, 292229574819840 ]

The subgroup \(S\) of order \(n\) is contained in a maximal subgroup \(M\) of the type \(2^{2+10+20}(M_{22}:2 \times S_3)\) in \(B\). The group \(M\) is the normalizer of a `2B`-pure Klein four group in \(B\), and the other class of normalizers of `2B`-pure Klein four groups does not contain subgroups of order \(n\). Thus the conjugates of \(S\) are uniquely determined by \(|S|\) and the property that they normalize `2B`-pure Klein four groups.

    gap> m:= mx[7];
    CharacterTable( "2^(2+10+20).(M22.2xS3)" )
    gap> Size( m );
    22858846741463040
    gap> nsg:= ClassPositionsOfMinimalNormalSubgroups( m );
    [ [ 1, 2 ] ]
    gap> SizesConjugacyClasses( m ){ nsg[1] };
    [ 1, 3 ]
    gap> GetFusionMap( m, b ){ nsg[1] };
    [ 1, 3 ]
    gap> List( cand, x -> Size( b ) / ( n * x ) );
    [ 770, 315/32 ]

Now consider the subgroup \(S'\) of order \(n\), which is contained in a maximal subgroup of the type \(2^{9+16}S_8(2)\) in \(B\). In order to prove that \(S'\) is \(B\)-conjugate to \(S\), it is enough to show that \(S'\) normalizes a `2B`-pure Klein four group.

The unique minimal normal subgroup \(V\) of \(2^{9+16}S_8(2)\) has order \(2^8\). Its involutions lie in the class `2B` of \(B\).

    gap> m:= mx[4];
    CharacterTable( "2^(9+16).S8(2)" )
    gap> nsg:= ClassPositionsOfMinimalNormalSubgroups( m );
    [ [ 1, 2 ] ]
    gap> SizesConjugacyClasses( m ){ nsg[1] };
    [ 1, 255 ]
    gap> GetFusionMap( m, b ){ nsg[1] };
    [ 1, 3 ]

The group \(V\) is central in the normal subgroup \(W = 2^{9+16}\), since all nonidentity elements of \(V\) lie in one conjugacy class of odd length. As a module for \(S_8(2)\), \(V\) is the unique irreducible eight-dimensional module in characteristic two.

    gap> CharacterDegrees( CharacterTable( "S8(2)" ) mod 2 );
    [ [ 1, 1 ], [ 8, 1 ], [ 16, 1 ], [ 26, 1 ], [ 48, 1 ], [ 128, 1 ],
      [ 160, 1 ], [ 246, 1 ], [ 416, 1 ], [ 768, 1 ], [ 784, 1 ],
      [ 2560, 1 ], [ 3936, 1 ], [ 4096, 1 ], [ 12544, 1 ], [ 65536, 1 ] ]

Hence we are done if the restriction of the \(S_8(2)\)-action on \(V\) to \(S'/W\) leaves a two-dimensional subspace of \(V\) invariant. In fact we show that already the restriction of the \(S_8(2)\)-action on \(V\) to the maximal subgroups of the structure \(2^{3+8}:(S_3 \times S_6)\) has a two-dimensional submodule.

These maximal subgroups have index \(5\,355\) in \(S_8(2)\). The primitive permutation representation of degree \(5\,355\) of \(S_8(2)\) and the irreducible eight-dimensional matrix representation of \(S_8(2)\) over the field with two elements are available via the GAP package AtlasRep, see [WPN+22]. We compute generators for an index \(5\,355\) subgroup in the matrix group via an isomorphism to the permutation group.

    gap> permg:= AtlasGroup( "S8(2)", NrMovedPoints, 5355 );
    <permutation group of size 47377612800 with 2 generators>
    gap> matg:= AtlasGroup( "S8(2)", Dimension, 8 );
    <matrix group of size 47377612800 with 2 generators>
    gap> hom:= GroupHomomorphismByImagesNC( matg, permg,
    >              GeneratorsOfGroup( matg ), GeneratorsOfGroup( permg ) );;
    gap> max:= PreImages( hom, Stabilizer( permg, 1 ) );;

These generators define the action of the index \(5\,355\) subgroup of \(S_8(2)\) on the eight-dimensional module. We compute the dimensions of the factors of an ascending composition series of this module.

    gap> m:= GModuleByMats( GeneratorsOfGroup( max ), GF(2) );;
    gap> comp:= MTX.CompositionFactors( m );;
    gap> List( comp, r -> r.dimension );
    [ 2, 4, 2 ]

##### 6.4-14 \(G = M\)

The group \(M\) contains exactly two conjugacy classes of solvable subgroups of order \(n = 2\,849\,934\,139\,195\,392\), and no larger solvable subgroups.

The maximal subgroups of the structure \(2^{1+24}_+.Co_1\) in the group \(M\) contain solvable subgroups \(S\) of order \(n\) and with the structure \(2^{1+24}_+.2^{4+12}.(S_3 \times 3^{1+2}_+:D_8)\), see [CCN+85, p. 234] and Section 6.4-10.

    gap> n:= 2^25 * MaxSolv.( "Co1" );
    2849934139195392

The solvable subgroups of maximal order in groups of the types \(2^{2+11+22}.(M_{24} \times S_3)\) and \(2^{[39]}.(L_3(2) \times 3S_6)\) have order \(n\).

    gap> 2^(2+11+22) * MaxSolv.( "M24" ) * 6 = n;
    true
    gap> 2^39 * 24 * 3 * 72 = n;
    true

For inspecting the other maximal subgroups of \(M\), we use the description from [NW13], which lists \(44\) classes of maximal subgroups of \(G\), and states that any possible other maximal subgroup of \(G\) has socle isomorphic to one of \(L_2(13)\), \(Sz(8)\), \(U_3(4)\), \(U_3(8)\); so these maximal subgroups are isomorphic to subgroups of the automorphism groups of these groups – the maximum of these group orders is smaller than \(n\), hence we may ignore these possible subgroups.

    gap> cand:= [ "L2(13)", "Sz(8)", "U3(4)", "U3(8)" ];;
    gap> List( cand, nam -> ExtensionInfoCharacterTable(
    > CharacterTable( nam ) ) );
    [ [ "2", "2" ], [ "2^2", "3" ], [ "", "4" ], [ "3", "(S3x3)" ] ]
    gap> ll:= List( cand, x -> Size( CharacterTable( x ) ) );
    [ 1092, 29120, 62400, 5515776 ]
    gap> 18 * ll[4];
    99283968
    gap> 2^39 * 24 * 3 * 72;
    2849934139195392

Remark added in December 2023: The classes of maximal subgroups of \(G\) are classified in [DLP23]. As a consequence, The result is that there are no maximal subgroups with socle \(Sz(8)\) or \(U_3(8)\), and there is one class of maximal subgroups of each of the isomorphism types \(L_2(13).2\) and \(U_3(4).4\).

Thus only the following maximal subgroups of \(M\) have order bigger than \(|S|\).

\(2.B\) | \(2^{1+24}_+.Co_1\) | \(3.Fi_{24}\) | \(2^2.{}^2E_6(2):S_3\)
\(2^{10+16}.O_{10}^+(2)\) | \(2^{2+11+22}.(M_{24} \times S_3)\) | \(3^{1+12}_+.2Suz.2\) | \(2^{5+10+20}.(S_3 \times L_5(2))\)
\(S_3 \times Th\) | \(2^{[39]}.(L_3(2) \times 3S_6)\) | \(3^8.O_8^-(3).2_3\) | \((D_{10} \times HN).2\)

For the subgroups \(2.B\), \(3.Fi_{24}\), \(3^{1+12}_+.2Suz.2\), \(S_3 \times Th\), and \((D_{10} \times HN).2\), the solvable subgroups of maximal order are smaller than \(n\).

    gap> List( [ 2 * MaxSolv.( "B" ),
    >            6 * MaxSolv.( "Fi24'" ),
    >            3^13 * 2 * MaxSolv.( "Suz" ) * 2,
    >            6 * MaxSolv.( "Th" ),
    >            10 * MaxSolv.( "HN" ) * 2 ], i -> Int( i / n ) );
    [ 0, 0, 0, 0, 0 ]

The subgroup \(2^2.{}^2E_6(2):S_3\) can be excluded by the fact that this group is only six times larger than the subgroup \(2.{}^2E_6(2):2\) of \(B\), but \(n\) is \(96\) times larger than the maximal solvable subgroup in \(B\).

    gap> n / MaxSolv.( "B" );
    96

The group \(3^8.O_8^-(3).2_3\) can be excluded by the fact that a solvable subgroup of order at least \(n\) would imply the existence of a solvable subgroup of index at most \(46\) in \(O_8^-(3).2_3\), which is not the case (see [CCN+85, p. 141]).

    gap> Int( 3^8 * Size( CharacterTable( "O8-(3)" ) ) * 2 / n );
    46

Similarly, the existence of a solvable subgroup of order at least \(n\) in \(2^{5+10+20}.(S_3 \times L_5(2))\) would imply the existence of a solvable subgroup of index at most \(723\) in \(L_5(2)\) and in turn of a solvable subgroup of index at most \(23\) in \(L_4(2)\), which is not the case (see [CCN+85, p. 70]).

    gap> Int( 2^(10+16) * Size( CharacterTable( "O10+(2)" ) ) / n );
    553350
    gap> Int( 2^(5+10+20) * 6 * Size( CharacterTable( "L5(2)" ) ) / n );
    723
    gap> Int( 723 / 31 );
    23

It remains to exclude the subgroup \(2^{10+16}.O_{10}^+(2)\), which means to show that \(O_{10}^+(2)\) does not contain a solvable subgroup of index at most \(553\,350\). If such a subgroup would exist then it would be contained in one of the following maximal subgroups of \(O_{10}^+(2)\) (see [CCN+85, p. 146]): in \(S_8(2)\) (of index at most \(1\,115\)), in \(2^8:O_8^+(2)\) (of index at most \(1\,050\)), in \(2^{10}:L_5(2)\) (of index at most \(241\)), in \((3 \times O_8^-(2)):2\) (of index at most \(27\)), in \((2^{1+12}_+:(S_3 \times A_8)\) (of index at most \(23\)), or in \(2^{3+12}:(S_3 \times S_3 \times L_3(2))\) (of index at most \(4\)). By [CCN+85, pp. 123, 85, 70, 89, 22], this is not the case.

    gap> index:= Int( 2^(10+16) * Size( CharacterTable( "O10+(2)" ) ) / n );
    553350
    gap> List( [ 496, 527, 2295, 19840, 23715, 118575 ], i -> Int( index / i ) );
    [ 1115, 1050, 241, 27, 23, 4 ]

As a consequence, we have shown that the largest solvable subgroups of \(M\) have order \(n\).

    gap> MaxSolv.( "M" ):= n;;

In order to prove the statement about the conjugacy of subgroups of order \(n\) in \(M\), we first show the following.

Lemma:

The group \(M\) contains exactly three conjugacy classes of `2B`-pure Klein four groups. Their normalizers in \(M\) have the orders \(50\,472\,333\,605\,150\,392\,320\), \(259\,759\,622\,062\,080\), and \(9\,567\,039\,651\,840\), respectively.

Proof. The idea is the same as for the Baby Monster group, see Section 6.4-13. Let \(V\) be a `2B`-pure Klein four group in \(M\), and set \(N = N_M(V)\). Let \(x \in V\) be an involution and set \(H = C_M(x)\), then \(H\) is maximal in \(M\) and has the structure \(2^{1+24}_+.Co_1\). The index of \(C = C_M(V) = C_H(V)\) in \(N\) divides \(6\), and \(C\) stabilizes the central involution in \(H\) and another `2B` involution.

The group \(H\) contains exactly five conjugacy classes of `2B` elements, three of them consist of elements that generate a `2B`-pure Klein four group together with \(x\).

    gap> m:= CharacterTable( "M" );;
    gap> h:= CharacterTable( "2^1+24.Co1" );
    CharacterTable( "2^1+24.Co1" )
    gap> pos:= Positions( GetFusionMap( h, m ), 3 );
    [ 2, 4, 7, 9, 16 ]
    gap> pos:= Filtered( Difference( pos, [ 2 ] ), i -> ForAny( pos,
    >             j -> NrPolyhedralSubgroups( h, 2, i, j ).number <> 0 ) );
    [ 4, 9, 16 ]

The two classes have lengths \(93\,150\) and \(7\,286\,400\), thus the index of \(C\) in \(H\) is one of these numbers.

    gap> SizesConjugacyClasses( h ){ pos };
    [ 16584750, 3222483264000, 87495303168000 ]

Next we compute the number \(n_0\) of `2B`-pure Klein four groups in \(M\).

    gap> nr:= NrPolyhedralSubgroups( m, 3, 3, 3 );
    rec( number := 87569110066985387357550925521828244921875,
      type := "V4" )
    gap> n0:= nr.number;;

The \(M\)-conjugacy class of \(V\) has length \([M:N] = [M:H] \cdot [H:C] / [N:C]\), where \([N:C]\) divides \(6\). We see that \([N:C] = 6\) in both cases.

    gap> cand:= List( pos, i -> Size( m ) / SizesCentralizers( h )[i] / 6 );
    [ 16009115629875684006343550944921875,
      3110635203347364905168577322802100000000,
      84458458854522392576698341855475200000000 ]
    gap> Sum( cand ) = n0;
    true

The orders of the normalizers of the three classes of `2B`-pure Klein four groups are as claimed.

    gap> List( cand, x -> Size( m ) / x );
    [ 50472333605150392320, 259759622062080, 9567039651840 ]

As we have seen above, the group \(M\) contains exactly the following (solvable) subgroups of order \(n\).

1. One class in \(2^{1+24}_+.Co_1\) type subgroups,

2. one class in \(2^{2+11+22}.(M_{24} \times S_3)\) type subgroups, and

3. two classes in \(2^{[39]}.(L_3(2) \times 3S_6)\) type subgroups.

Note that \(2^{[39]}.(L_3(2) \times 3S_6)\) contains an elementary abelian normal subgroup of order eight whose involutions lie in the class `2B`, see [CCN+85, p. 234]. As a module for the group \(L_3(2)\), this normal subgroup is irreducible, and the restriction of the action to the two classes of \(S_4\) type subgroups fixes a one- and a two-dimensional subspace, respectively. Hence we have one class of subgroups of order \(n\) that centralize a `2B` element and one class of subgroups of order \(n\) that normalize a `2B`-pure Klein four group. Clearly the subgroups in the first class coincide with the subgroups of order \(n\) in \(2^{1+24}_+.Co_1\) type subgroups. By the above classification of `2B`-pure Klein four groups in \(M\), the subgroups in the second class coincide with the subgroups of order \(n\) in \(2^{2+11+22}.(M_{24} \times S_3)\) type subgroups.

It remains to show that the subgroups of order \(n\) do not stabilize both a `2B` element and a `2B`-pure Klein four group. We do this by direct computations with a \(2^{2+11+22}.(M_{24} \times S_3)\) type group, which is available via the AtlasRep package, see [WPN+22].

First we fetch the group, and factor out the largest solvable normal subgroup, by suitable actions on blocks.

    gap> g:= AtlasGroup( "2^(2+11+22).(M24xS3)" );
    <permutation group of size 50472333605150392320 with 2 generators>
    gap> NrMovedPoints( g );
    294912
    gap> bl:= Blocks( g, MovedPoints( g ) );;
    gap> Length( bl );
    147456
    gap> hom1:= ActionHomomorphism( g, bl, OnSets );;
    gap> act1:= Image( hom1 );;
    gap> Size( g ) / Size( act1 );
    8192
    gap> bl2:= Blocks( act1, MovedPoints( act1 ) );;
    gap> Length( bl2 );
    72
    gap> hom2:= ActionHomomorphism( act1, bl2, OnSets );;
    gap> act2:= Image( hom2 );;
    gap> Size( act2 );
    1468938240
    gap> Size( MathieuGroup( 24 ) ) * 6;
    1468938240
    gap> bl3:= AllBlocks( act2 );;
    gap> List( bl3, Length );
    [ 24, 3 ]
    gap> bl3:= Orbit( act2, bl3[2], OnSets );;
    gap> hom3:= ActionHomomorphism( act2, bl3, OnSets );;
    gap> act3:= Image( hom3 );;

Now we compute an isomorphism from the factor group of type \(M_{24}\) to the group that belongs to GAP's table of marks. Then we use the information from the table of marks to compute a solvable subgroup of maximal order in \(M_{24}\) (which is \(13\,824\)), and take the preimage under the isomorphism. Finally, we take the preimage of this group in the original group.

    gap> tom:= TableOfMarks( "M24" );;
    gap> tomgroup:= UnderlyingGroup( tom );;
    gap> iso:= IsomorphismGroups( act3, tomgroup );;
    gap> pos:= Positions( OrdersTom( tom ), 13824 );
    [ 1508 ]
    gap> sub:= RepresentativeTom( tom, pos[1] );;
    gap> pre:= PreImages( iso, sub );;
    gap> pre:= PreImages( hom3, pre );;
    gap> pre:= PreImages( hom2, pre );;
    gap> pre:= PreImages( hom1, pre );;
    gap> Size( pre ) = n;
    true

The subgroups stabilizes a Klein four group. It does not stabilize a `2B` element because its centre is trivial.

    gap> pciso:= IsomorphismPcGroup( pre );;
    gap> Size( Centre( Image( pciso ) ) );
    1

#### 6.5 Proof of the Corollary

With the computations in the previous sections, we have collected the information that is needed to show the corollary stated in Section 6.1.

    gap> Filtered( Set( RecNames( MaxSolv ) ),
    >              x -> MaxSolv.( x )^2 >= Size( CharacterTable( x ) ) );
    [ "Fi23", "J2", "J2.2", "M11", "M12", "M22.2" ]

[Top of Book] [Contents] [Previous Chapter] [Next Chapter]
Goto Chapter: Top 1 2 3 4 5 6 7 8 9 10 11 Bib Ind

generated by GAPDoc2HTML