GAP (HAP commands) - Chapter 8: Cohomology rings and Steenrod operations for groups

Goto Chapter: Top 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 Bib Ind
[Top of Book] [Contents] [Previous Chapter] [Next Chapter]

[MathJax off]

8 Cohomology rings and Steenrod operations for groups
8.1 Mod-\(p\) cohomology rings of finite groups
8.1-1 Ring presentations (for the commutative \(p=2\) case)
8.2 Poincare Series for Mod-\(p\) cohomology
8.3 Functorial ring homomorphisms in Mod-\(p\) cohomology
8.3-1 Testing homomorphism properties
8.3-2 Testing functorial properties
8.3-3 Computing with larger groups
8.4 Steenrod operations for finite \(2\)-groups
8.5 Steenrod operations on the classifying space of a finite \(p\)-group
8.6 Mod-\(p\) cohomology rings of crystallographic groups
8.6-1 Poincare series for crystallographic groups
8.6-2 Mod \(2\) cohomology rings of \(3\)-dimensional crystallographic groups

### 8 Cohomology rings and Steenrod operations for groups

#### 8.1 Mod-\(p\) cohomology rings of finite groups

For a finite group \(G\), prime \(p\) and positive integer \(deg\) the function `ModPCohomologyRing(G,p,deg)` computes a finite dimensional graded ring equal to the cohomology ring \(H^{\le deg}(G,\mathbb Z_p) := H^\ast(G,\mathbb Z_p)/\{x=0\ :\ {\rm degree}(x)>deg \}\) .

The following example computes the first \(14\) degrees of the cohomology ring \(H^\ast(M_{11},\mathbb Z_2)\) where \(M_{11}\) is the Mathieu group of order \(7920\). The ring is seen to be generated by three elements \(a_3, a_4, a_6\) in degrees \(3,4,5\).

    gap> G:=MathieuGroup(11);;
    gap> p:=2;;deg:=14;;
    gap> A:=ModPCohomologyRing(G,p,deg);
    <algebra over GF(2), with 20 generators>

    gap> gns:=ModPRingGenerators(A);
    [ v.1, v.6, v.8+v.10, v.13 ]
    gap> List(gns,A!.degree);
    [ 0, 3, 4, 5 ]

The following additional command produces a rational function \(f(x)\) whose series expansion \(f(x) = \sum_{i=0}^\infty f_ix^i\) has coefficients \(f_i\) which are guaranteed to satisfy \(f_i = \dim H^i(G,\mathbb Z_p)\) in the range \(0\le i\le deg\). We refer to \(f(x)\) as the Poincare series for the group at the prime \(p=2\).

    gap> f:=PoincareSeries(A);
    (x_1^4-x_1^3+x_1^2-x_1+1)/(x_1^6-x_1^5+x_1^4-2*x_1^3+x_1^2-x_1+1)

    gap> Let's use f to list the first few cohomology dimensions
    gap> ExpansionOfRationalFunction(f,deg);
    [ 1, 0, 0, 1, 1, 1, 1, 1, 2, 2, 1, 2, 3, 2, 2 ]

An alternative command for computing the Poincare series is the following. In this alternative we choose to ensure correctness in degrees \(\le 100\).

    gap> PoincareSeriesPrimePart(MathieuGroup(11),2,100);
    The series is guaranteed correct for group cohomology in degrees < 101
    (x_1^4-x_1^3+x_1^2-x_1+1)/(x_1^6-x_1^5+x_1^4-2*x_1^3+x_1^2-x_1+1)

If one needs to verify that the Poincare series is valid in all degrees then more work is required. One readily implemented (but computationally non-optimal) approach is to use Peter Symmonds result [Sym10] that: if a non-cyclic finite group \(G\) has a faithful complex representation equal to a sum of irreducibles of dimensions \(n_i\) then the cohomology ring \(H^\ast(G,\mathbb Z_p)\) is generated by elements of degree at most \(\sum n_i^2\); a degree bound for the relations is \(2 \sum n_i^2\). The following commands use this bound, in conjunction with Webb's result 7.14 on the Quillen complex, to obtained a Poincare series that is guaranteed correct in all degree.

    gap> G:=MathieuGroup(11);;
    gap> h:=HomologicalGroupDecomposition(G,2);;

    gap> ModPCohomologyPresentationBounds(h[1][1]);
    rec( generators_degree_bound := 4, relators_degree_bound := 8 )
    gap> A:=ModPCohomologyRing(h[1][1],2,9);;F:=PresentationOfGradedStructureConstantAlgebra(A);;f11:=HilbertPoincareSeries(F);
    (x_1^2-x_1+1)/(x_1^4-2*x_1^3+2*x_1^2-2*x_1+1)

    gap> ModPCohomologyPresentationBounds(h[1][2]);
    rec( generators_degree_bound := 9, relators_degree_bound := 18 )
    gap> A:=ModPCohomologyRing(h[1][2],2,19);;F:=PresentationOfGradedStructureConstantAlgebra(A);;f12:=HilbertPoincareSeries(F);
    (x_1^2+1)/(x_1^4-x_1^3-x_1+1)

    gap> ModPCohomologyPresentationBounds(h[2][1]);
    rec( generators_degree_bound := 4, relators_degree_bound := 8 )
    gap> A:=ModPCohomologyRing(h[2][1],2,9);;F:=PresentationOfGradedStructureConstantAlgebra(A);;f21:=HilbertPoincareSeries(F);
    (1)/(x_1^2-2*x_1+1)

    gap> f11+f12-f21;
    (x_1^4-x_1^3+x_1^2-x_1+1)/(x_1^6-x_1^5+x_1^4-2*x_1^3+x_1^2-x_1+1)

##### 8.1-1 Ring presentations (for the commutative \(p=2\) case)

The cohomology ring \(H^\ast(G,\mathbb Z_p)\) is graded commutative which, in the case \(p=2\), implies strictly commutative. The following additional commands can be applied in the \(p=2\) setting to determine a presentation for a graded commutative ring \(F\) that is guaranteed to be isomorphic to the cohomology ring \(H^\ast(G,\mathbb Z_p)\) in degrees \(i\le deg\). If \(deg\) is chosen "sufficiently large" then \(F\) will be isomorphic to the cohomology ring.

    gap> F:=PresentationOfGradedStructureConstantAlgebra(A);
    Graded algebra GF(2)[ x_1, x_2, x_3 ] / [ x_1^2*x_2+x_3^2
     ] with indeterminate degrees [ 3, 4, 5 ]

The additional command

    gap> p:=HilbertPoincareSeries(F);
    (x_1^4-x_1^3+x_1^2-x_1+1)/(x_1^6-x_1^5+x_1^4-2*x_1^3+x_1^2-x_1+1)

invokes a call to Singular in order to calculate the Poincare series of the graded algebra \(F\).

#### 8.2 Poincare Series for Mod-\(p\) cohomology

For a finite \(p\)-group \(G\) the command `PoincarePolynomial(G)` returns a rational function \(f(x)=p(x)/q(x)\) whose series expansion \(f(x) = \sum_{i=0}^\infty f_ix^i\) has coefficients \(f_i\) that are guaranteed to satisfy \(f_i = \dim H^i(G,\mathbb Z_p)\) in the range \(0\le i < 1+ deg\) for some displayed value of \(deg\). Furthermore, the coefficients \(f_i\) are guaranteed to be integers for all \(0\le i\le 1000\) and the order of the pole of \(f(x)\) at \(x=1\) is guaranteed to equal the \(p\)-rank of \(G\).

    gap> G:=SmallGroup(3^4,10);;
    gap> StructureDescription(G);
    "C3 . ((C3 x C3) : C3) = (C3 x C3) . (C3 x C3)"
    gap> f:=PoincareSeries(G);
    The series is guaranteed correct for group cohomology in degrees < 14
    (-x_1^3+x_1^2+1)/(x_1^6-2*x_1^5+2*x_1^4-2*x_1^3+2*x_1^2-2*x_1+1)

If a higher value of \(deg\) is required then this can be entered as an optional second argument. For instance, the following increases the value to \(deg=100\).

    gap> f:=PoincareSeries(G,100);
    The series is guaranteed correct for group cohomology in degrees < 101
    (-x_1^3+x_1^2+1)/(x_1^6-2*x_1^5+2*x_1^4-2*x_1^3+2*x_1^2-2*x_1+1)

As mentioned above, one approach to verifying that the Poincare series is valid in all degrees is to use Peter Symmonds result [Sym10] that: if a non-cyclic finite group \(G\) has a faithful complex representation equal to a sum of irreducibles of dimensions \(n_i\) then the cohomology ring \(H^\ast(G,\mathbb Z_p)\) is generated by elements of degree at most \(\sum n_i^2\); a degree bound for the relations is \(2 \sum n_i^2\). Thus, if we use at least \(\sum n_i^2\) degrees of a resolution to construct a presentation for the cohomology ring then the presented ring maps surjectively onto the actual cohomology ring. Furthermore, if this surjection is a bijection in the first \(2 \sum n_i^2\) degrees then it is necessarily an isomorphism in all degrees.

The following commands use this approach to obtain a guaranteed presentation and Poincare series for the Sylow \(2\)-subgroup of the Mathieu group \(M_{12}\).

    gap> G:=SylowSubgroup(MathieuGroup(12),2);;
    gap> ModPCohomologyPresentationBounds(G);
    rec( generators_degree_bound := 16, relators_degree_bound := 32 )
    gap> A:=ModPCohomologyRing(G,16);;
    gap> F:=PresentationOfGradedStructureConstantAlgebra(A);
    Graded algebra GF(2)[ x_1, x_2, x_3, x_4, x_5, x_6, x_7 ] /
    [ x_1*x_3, x_1*x_2, x_1*x_4, x_2*x_3^2+x_3^3+x_3*x_4+x_3*x_5,
      x_2*x_6+x_3*x_6+x_4*x_5, x_2*x_3*x_4+x_3^2*x_4+x_3*x_6,
      x_2^2*x_4+x_3^2*x_4+x_3*x_6+x_4^2, x_3^2*x_6+x_3*x_4^2+x_3*x_4*x_5,
      x_2*x_4*x_5+x_4*x_6, x_3^2*x_4*x_5+x_3*x_4*x_6+x_3*x_5*x_6,
      x_1^3*x_6+x_1^2*x_7+x_1*x_5*x_6+x_3*x_5*x_6+x_4*x_5^2+x_6^2,
      x_3*x_4^2*x_5+x_3*x_6^2 ] with indeterminate degrees [ 1, 1, 1, 2, 2, 3, 4 ]
    gap> f:=HilbertPoincareSeries(F);
    (1)/(-x_1^3+3*x_1^2-3*x_1+1)

    gap> ff:=PoincareSeries(G,32);
    The series is guaranteed correct for group cohomology in degrees < 33
    (1)/(-x_1^3+3*x_1^2-3*x_1+1)

An alternative approach to obtaining a guaranteed presentation is to implement Len even's spectral sequence proof of the finite generation of cohomology rings of finite groups. The following example determines a guaranteed presentation in this way for the cohomology ring \(H^\ast(Syl_2(M_{12}),\mathbb Z_2)\). The Lyndon-Hochschild-Serre spectral sequence, and Groebner basis routines from Singular (for commutative rings), are used to determine how much of a resolution is needed to compute the guaranteed correct presentation.

    gap> G:=SylowSubgroup(MathieuGroup(12),2);;
    gap> F:=Mod2CohomologyRingPresentation(G);
    Alpha version of completion test code will be used. This needs further work.
    Graded algebra GF(2)[ x_1, x_2, x_3, x_4, x_5, x_6, x_7 ] /
    [ x_2*x_3, x_1*x_2, x_2*x_4, x_1^3+x_1^2*x_3+x_1*x_5,
      x_1*x_3*x_4+x_1*x_3*x_5+x_3^2*x_4+x_1*x_6+x_3*x_6+x_4*x_5,
      x_1^2*x_4+x_1^2*x_5+x_1*x_3*x_5+x_3^2*x_4+x_1*x_6+x_4^2,
      x_1^2*x_3^2+x_1^2*x_5+x_1*x_3*x_5+x_1*x_6+x_3*x_6+x_4^2+x_4*x_5,
      x_1^2*x_6+x_1*x_3*x_6+x_1*x_4*x_5+x_3^2*x_6+x_3*x_4^2+x_3*x_4*x_5,
      x_1*x_3^2*x_5+x_3^3*x_4+x_1*x_3*x_6+x_1*x_4^2+x_3^2*x_6+x_3*x_4^2+x_4*x_6,
      x_1^2*x_3*x_5+x_1*x_3*x_6+x_1*x_4^2+x_1*x_5^2,
      x_3^3*x_6+x_3^2*x_4^2+x_3^2*x_4*x_5+x_3*x_4*x_6+x_3*x_5*x_6+x_4^3+x_4*x_5^2,
      x_1*x_3^2*x_6+x_1*x_4*x_6+x_2^2*x_7+x_2*x_5*x_6+x_3*x_4*x_6+x_3*x_5*x_6+x_6^2,
      x_1^2*x_5^2+x_1*x_3*x_5^2+x_3^2*x_4^2+x_3^2*x_4*x_5+x_2^2*x_7+x_2*x_5*x_6+x_3*x_5*x_6+x_6^2 ]
    with indeterminate degrees [ 1, 1, 1, 2, 2, 3, 4 ]

    gap> f:=HilbertPoincareSeries(F);
    (1)/(-x_1^3+3*x_1^2-3*x_1+1)

#### 8.3 Functorial ring homomorphisms in Mod-\(p\) cohomology

The following example constructs the ring homomorphism

\(F\colon H^{\le deg}(G,\mathbb Z_p) \rightarrow H^{\le deg}(H,\mathbb Z_p)\)

induced by the group homomorphism \(f\colon H\rightarrow G\) with \(H=A_5\), \(G=S_5\), \(f\) the canonical inclusion of the alternating group into the symmetric group, \(p=2\) and \(deg=7\).

    gap> G:=SymmetricGroup(5);;H:=AlternatingGroup(5);;
    gap> f:=GroupHomomorphismByFunction(H,G,x->x);;
    gap> p:=2;; deg:=7;;
    gap> F:=ModPCohomologyRing(f,p,deg);
    [ v.1, v.2, v.4+v.6, v.5, v.7, v.8, v.9, v.12+v.15, v.13, v.14, v.16+v.17,
      v.18, v.19, v.20, v.22+v.24+v.28, v.23, v.25, v.26, v.27 ] ->
    [ v.1, 0*v.1, v.4+v.5+v.6, 0*v.1, v.7+v.8, 0*v.1, 0*v.1, v.14+v.15, 0*v.1,
      0*v.1, v.16+v.17+v.19, 0*v.1, 0*v.1, 0*v.1, v.22+v.23+v.26+v.27+v.28,
      v.25, 0*v.1, 0*v.1, 0*v.1 ]

##### 8.3-1 Testing homomorphism properties

The following commands are consistent with \(F\) being a ring homomorphism.

    gap> x:=Random(Source(F));
    v.4+v.6+v.8+v.9+v.12+v.13+v.14+v.15+v.18+v.20+v.22+v.24+v.25+v.28+v.32+v.35
    gap> y:=Random(Source(F));
    v.1+v.2+v.7+v.9+v.13+v.23+v.26+v.27+v.32+v.33+v.34+v.35
    gap> Image(F,x)+Image(F,y)=Image(F,x+y);
    true
    gap> Image(F,x)*Image(F,y)=Image(F,x*y);
    true

##### 8.3-2 Testing functorial properties

The following example takes two "random" automorphisms \(f,g\colon K\rightarrow K\) of the group \(K\) of order \(24\) arising as the direct product \(K=C_3\times Q_8\) and constructs the three ring isomorphisms \(F,G,FG\colon H^{\le 5}(K,\mathbb Z_2) \rightarrow H^{\le 5}(K,\mathbb Z_2)\) induced by \(f, g\) and the composite \(f\circ g\). It tests that \(FG\) is indeed the composite \(G\circ F\). Note that when we create the ring \(H^{\le 5}(K,\mathbb Z_2)\) twice in GAP we obtain two canonically isomorphic but distinct implimentations of the ring. Thus the canocial isomorphism between these distinct implementations needs to be incorporated into the test. Note also that GAP defines \(g\ast f = f\circ g\).

    gap> K:=SmallGroup(24,11);;
    gap> aut:=AutomorphismGroup(K);;
    gap> f:=Elements(aut)[5];;
    gap> g:=Elements(aut)[8];;
    gap> fg:=g*f;;
    gap> F:=ModPCohomologyRing(f,2,5);
    [ v.1, v.2, v.3, v.4, v.5, v.6, v.7 ] -> [ v.1, v.2+v.3, v.3, v.4+v.5, v.5,
      v.6, v.7 ]
    gap> G:=ModPCohomologyRing(g,2,5);
    [ v.1, v.2, v.3, v.4, v.5, v.6, v.7 ] -> [ v.1, v.2+v.3, v.2, v.5, v.4+v.5,
      v.6, v.7 ]
    gap> FG:=ModPCohomologyRing(fg,2,5);
    [ v.1, v.2, v.3, v.4, v.5, v.6, v.7 ] -> [ v.1, v.3, v.2, v.4, v.4+v.5, v.6,
      v.7 ]

    gap> sF:=Source(F);;tF:=Target(F);;
    gap> sG:=Source(G);;
    gap> tGsF:=AlgebraHomomorphismByImages(tF,sG,Basis(tF),Basis(sG));;
    gap> List(GeneratorsOfAlgebra(sF),x->Image(G,Image(tGsF,Image(F,x))));
    [ v.1, v.3, v.2, v.4, v.4+v.5, v.6, v.7 ]

##### 8.3-3 Computing with larger groups

Mod-\(p\) cohomology rings of finite groups are constructed as the rings of stable elements in the cohomology of a (non-functorially) chosen Sylow \(p\)-subgroup and thus require the construction of a free resolution only for the Sylow subgroup. However, to ensure the functoriality of induced cohomology homomorphisms the above computations construct free resolutions for the entire groups \(G,H\). This is a more expensive computation than finding resolutions just for Sylow subgroups.

The default algorithm used by the function `ModPCohomologyRing()` for constructing resolutions of a finite group \(G\) is `ResolutionFiniteGroup()` or `ResolutionPrimePowerGroup()` in the case when \(G\) happens to be a group of prime-power order. If the user is able to construct the first \(deg\) terms of free resolutions \(RG, RH\) for the groups \(G, H\) then the pair `[RG,RH]` can be entered as the third input variable of `ModPCohomologyRing()`.

For instance, the following example constructs the ring homomorphism

\(F\colon H^{\le 7}(A_6,\mathbb Z_2) \rightarrow H^{\le 7}(S_6,\mathbb Z_2)\)

induced by the the canonical inclusion of the alternating group \(A_6\) into the symmetric group \(S_6\).

    gap> G:=SymmetricGroup(6);;
    gap> H:=AlternatingGroup(6);;
    gap> f:=GroupHomomorphismByFunction(H,G,x->x);;
    gap> RG:=ResolutionFiniteGroup(G,7);;
    gap> RH:=ResolutionFiniteSubgroup(RG,H);;
    gap> F:=ModPCohomologyRing(f,2,[RG,RH]);
    [ v.1, v.2+v.3, v.6+v.8+v.10, v.7+v.9, v.11+v.12, v.13+v.15+v.16+v.18+v.19,
      v.14+v.16+v.19, v.17, v.22, v.23+v.28+v.32+v.35,
      v.24+v.26+v.27+v.29+v.32+v.33+v.35, v.25+v.26+v.27+v.29+v.32+v.33+v.35,
      v.30+v.32+v.33+v.34+v.35, v.36+v.39+v.43+v.45+v.47+v.49+v.50+v.55,
      v.38+v.45+v.47+v.49+v.50+v.55, v.40,
      v.41+v.43+v.45+v.47+v.48+v.49+v.50+v.53+v.55,
      v.42+v.43+v.45+v.46+v.47+v.49+v.53+v.54, v.44+v.45+v.46+v.47+v.49+v.53+v.54,
      v.51+v.52, v.58+v.60, v.59+v.68+v.73+v.77+v.81+v.83,
      v.62+v.68+v.74+v.77+v.78+v.80+v.81+v.83+v.84,
      v.63+v.69+v.73+v.74+v.78+v.80+v.84, v.64+v.68+v.73+v.77+v.81+v.83, v.65,
      v.66+v.75+v.81, v.67+v.68+v.69+v.70+v.73+v.74+v.78+v.80+v.84,
      v.71+v.72+v.73+v.76+v.77+v.78+v.80+v.82+v.83+v.84, v.79 ] ->
    [ v.1, 0*v.1, v.4+v.5+v.6, 0*v.1, v.8, v.8, 0*v.1, v.7, 0*v.1,
      v.12+v.13+v.14+v.15, v.12+v.13+v.14+v.15, v.12+v.13+v.14+v.15,
      v.12+v.13+v.14+v.15, v.18+v.19, 0*v.1, 0*v.1, v.18+v.19, v.18+v.19,
      v.18+v.19, v.16+v.17, 0*v.1, v.25, v.22+v.24+v.25+v.26+v.27+v.28,
      v.22+v.24+v.25+v.26+v.27+v.28, 0*v.1, 0*v.1, v.25, v.22+v.24+v.26+v.27+v.28,
      v.22+v.24+v.26+v.27+v.28, v.23 ]

#### 8.4 Steenrod operations for finite \(2\)-groups

The command `CohomologicalData(G,n)` prints complete information for the cohomology ring \(H^\ast(G, Z_2 )\) and steenrod operations for a \(2\)-group \(G\) provided that the integer \(n\) is at least the maximal degree of a generator or relator in a minimal set of generatoirs and relators for the ring.

The following example produces complete information on the Steenrod algebra of group number \(8\) in GAP's library of groups of order \(32\). Groebner basis routines (for commutative rings) from Singular are called in the example. (This example take over 2 hours to run. Most other groups of order 32 run significantly quicker.)

    gap> CohomologicalData(SmallGroup(32,8),12);

    Integer argument is large enough to ensure completeness of cohomology ring presentation.

    Group number: 8
    Group description: C2 . ((C4 x C2) : C2) = (C2 x C2) . (C4 x C2)

    Cohomology generators
    Degree 1: a, b
    Degree 2: c, d
    Degree 3: e
    Degree 5: f, g
    Degree 6: h
    Degree 8: p

    Cohomology relations
    1: f^2
    2: c*h+e*f
    3: c*f
    4: b*h+c*g
    5: b*e+c*d
    6: a*h
    7: a*g
    8: a*f+b*f
    9: a*e+c^2
    10: a*c
    11: a*b
    12: a^2
    13: d*e*h+e^2*g+f*h
    14: d^2*h+d*e*f+d*e*g+f*g
    15: c^2*d+b*f
    16: b*c*g+e*f
    17: b*c*d+c*e
    18: b^2*g+d*f
    19: b^2*c+c^2
    20: b^3+a*d
    21: c*d^2*e+c*d*g+d^2*f+e*h
    22: c*d^3+d*e^2+d*h+e*f+e*g
    23: b^2*d^2+c*d^2+b*f+e^2
    24: b^3*d
    25: d^3*e^2+d^2*e*f+c^2*p+h^2
    26: d^4*e+b*c*p+e^2*g+g*h
    27: d^5+b*d^2*g+b^2*p+f*g+g^2

    Poincare series
    (x^5+x^2+1)/(x^8-2*x^7+2*x^6-2*x^5+2*x^4-2*x^3+2*x^2-2*x+1)

    Steenrod squares
    Sq^1(c)=0
    Sq^1(d)=b*b*b+d*b
    Sq^1(e)=c*b*b
    Sq^2(e)=e*d+f
    Sq^1(f)=c*d*b*b+d*d*b*b
    Sq^2(f)=g*b*b
    Sq^4(f)=p*a
    Sq^1(g)=d*d*d+g*b
    Sq^2(g)=0
    Sq^4(g)=c*d*d*d*b+g*d*b*b+g*d*d+p*a+p*b
    Sq^1(h)=c*d*d*b+e*d*d
    Sq^2(h)=d*d*d*b*b+c*d*d*d+g*c*b
    Sq^4(h)=d*d*d*d*b*b+g*e*d+p*c
    Sq^1(p)=c*d*d*d*b
    Sq^2(p)=d*d*d*d*b*b+c*d*d*d*d
    Sq^4(p)=d*d*d*d*d*b*b+d*d*d*d*d*d+g*d*d*d*b+g*g*d+p*d*d

#### 8.5 Steenrod operations on the classifying space of a finite \(p\)-group

The following example constructs the first eight degrees of the mod-\(3\) cohomology ring \(H^\ast(G,\mathbb Z_3)\) for the group \(G\) number 4 in GAP's library of groups of order \(81\). It determines a minimal set of ring generators lying in degree \(\le 8\) and it evaluates the Bockstein operator on these generators. Steenrod powers for \(p\ge 3\) are not implemented as no efficient method of implementation is known.

    gap> G:=SmallGroup(81,4);;
    gap> A:=ModPSteenrodAlgebra(G,8);;
    gap> List(ModPRingGenerators(A),x->Bockstein(A,x));
    [ 0*v.1, 0*v.1, v.5, 0*v.1, (Z(3))*v.7+v.8+(Z(3))*v.9 ]

#### 8.6 Mod-\(p\) cohomology rings of crystallographic groups

Mod \(p\) cohomology ring computations can be attempted for any group \(G\) for which we can compute sufficiently many terms of a free \(ZG\)-resolution with contracting homotopy. The contracting homotopy is not needed if only the dimensions of the cohomology in each degree are sought. Crystallographic groups are one class of infinite groups where such computations can be attempted.

##### 8.6-1 Poincare series for crystallographic groups

Consider the space group \(G=SpaceGroupOnRightIT(3,226,'1')\). The following computation computes the infinite series

\((-2x^4+2x^2+1)/(-x^5+2x^4-x^3+x^2-2x+1)\)

in which the coefficient of the monomial \(x^n\) is guaranteed to equal the dimension of the vector space \(H^n(G,\mathbb Z_2)\) in degrees \(n\le 14\). One would need to involve a theoretical argument to establish that this equality in fact holds in every degree \(n\ge 0\).

    gap> G:=SpaceGroupIT(3,226);
    SpaceGroupOnRightIT(3,226,'1')
    gap> R:=ResolutionSpaceGroup(G,15);
    Resolution of length 15 in characteristic 0 for <matrix group with
    8 generators> .
    No contracting homotopy available.

    gap> D:=List([0..14],n->Cohomology(HomToIntegersModP(R,2),n));
    [ 1, 2, 5, 9, 11, 15, 20, 23, 28, 34, 38, 44, 51, 56, 63 ]

    gap> PoincareSeries(D,14);
    (-2*x_1^4+2*x_1^2+1)/(-x_1^5+2*x_1^4-x_1^3+x_1^2-2*x_1+1)

Consider the space group \(SpaceGroupOnRightIT(3,103,'1')\). The following computation uses a different construction of a free resolution to compute the infinite series

\( (x^3+2x^2+2x+1)/(-x+1) \)

in which the coefficient of the monomial \(x^n\) is guaranteed to equal the dimension of the vector space \(H^n(G,\mathbb Z_2)\) in degrees \(n\le 99\). The final commands show that \(G\) acts on a (cubical) cellular decomposition of \(\mathbb R^3\) with cell ctabilizers being either trivial or cyclic of order \(2\) or \(4\). From this extra calculation it follows that the cohomology is periodic in degrees greater than \(3\) and that the Poincare series is correct in every degree \(n \ge 0\).

    gap> G:=SpaceGroupIT(3,103);
    SpaceGroupOnRightIT(3,103,'1')
    gap> R:=ResolutionCubicalCrystGroup(G,100);
    Resolution of length 100 in characteristic 0 for <matrix group with 6 generators> .

    gap> D:=List([0..99],n->Cohomology(HomToIntegersModP(R,2),n));;
    gap> PoincareSeries(D,99);
    (x_1^3+2*x_1^2+2*x_1+1)/(-x_1+1)

    #Torsion subgroups are cyclic
    gap> B:=CrystGFullBasis(G);;
    gap> C:=CrystGcomplex(GeneratorsOfGroup(G),B,1);;
    gap> for n in [0..3] do
    > for k in [1..C!.dimension(n)] do
    > Print(StructureDescription(C!.stabilizer(n,k)),"  ");
    > od;od;
    C4  C2  C4  1  1  C4  C2  C4  1  1  1  1

##### 8.6-2 Mod \(2\) cohomology rings of \(3\)-dimensional crystallographic groups

Computations in the integral cohomology of a crystallographic group are illustrated in Section 1.19. The commands underlying that illustration could be further developed and adapted to mod \(p\) cohomology. Indeed, the authors of the paper [LY24a] have developed commands for accessing the mod \(2\) cohomology of \(3\)-dimensional crystallographic groups with the aim of establishing a connection between these rings and the lattice structure of crystals with space group symmetry. Their code is available at the github repository [LY24b]. In particular, their code contains the command

- `SpaceGroupCohomologyRingGapInterface(ITC)`

that inputs an integer in the range \(1\le ITC\le 230\) corresponding to the numbering of a \(3\)-dimensional space group \(G\) in the International Table for Crystallography. This command returns

- a presentation for the mod \(2\) cohomology ring \(H^\ast(G,\mathbb Z_2)\). The presentation is guaranteed to be correct for low degree cohomology. In cases where the cohomology is periodic in degrees \( \ge 5\) (which can be tested using `IsPeriodicSpaceGroup(G)`) the presentation is guaranteed correct in all degrees. In non-periodic cases some additional mathematical argument needs to be provided to be mathematically sure that the presentation is correct in all degrees.

- the Lieb-Schultz-Mattis anomaly (degree-3 cocycles) associated with the Irreducible Wyckoff Position (see the paper [LY24a] for a definition).

The command `SpaceGroupCohomologyRingGapInterface(ITC)` is fast for most groups (a few seconds to a few minutes) but can be very slow for certain space groups (e.g. ITC \(= 228\) and ITC \(= 142\)). The following illustration assumes that two relevant files have been downloaded from [LY24b] and illustrates the command for ITC \( =30\) and ITC \(=216\).

    gap> Read("SpaceGroupCohomologyData.gi");        #These two files must be
    gap> Read("SpaceGroupCohomologyFunctions.gi");   #downloaded from
    gap>       #https://github.com/liuchx1993/Space-Group-Cohomology-and-LSM/

    gap> IsPeriodicSpaceGroup(SpaceGroupIT(3,30));
    true

    gap> SpaceGroupCohomologyRingGapInterface(30);
    ===========================================
    Mod-2 Cohomology Ring of Group No. 30:
    Z2[Ac,Am,Ax,Bb]/<R2,R3,R4>
    R2:  Ac.Am  Am^2  Ax^2+Ac.Ax
    R3:  Am.Bb
    R4:  Bb^2
    ===========================================
    LSM:
    2a Ac.Bb+Ax.Bb
    2b Ax.Bb
    true

    gap> IsPeriodicSpaceGroup(SpaceGroupIT(3,216));
    false

    gap> SpaceGroupCohomologyRingGapInterface(216);
    ===========================================
    Mod-2 Cohomology Ring of Group No. 216:
    Z2[Am,Ba,Bb,Bxyxzyz,Ca,Cb,Cc,Cxyz]/<R4,R5,R6>
    R4:  Am.Ca  Am.Cb  Ba.Bxyxzyz+Am.Cc  Bb^2+Am.Cc+Ba.Bb  Bb.Bxyxzyz+Am^2.Bb+Am.Cxyz  Bxyxzyz^2
    R5:  Bxyxzyz.Ca  Ba.Cb+Bb.Ca  Bb.Cb+Bb.Ca  Bxyxzyz.Cb  Bxyxzyz.Cc  Ba.Cxyz+Am.Ba.Bb+Bb.Cc  Bb.Cxyz+Am^2.Cc+Am.Ba.Bb+Bb.Cc  Bxyxzyz.Cxyz+Am^3.Bb+Am^2.Cxyz
    ===========================================
    LSM:
    4a Ca+Cc+Cxyz
    4b Cb+Cc+Cxyz
    4c Cb+Cxyz
    4d Cxyz
    true

In the example the naming convention for ring generators follows the paper [LY24a].

[Top of Book] [Contents] [Previous Chapter] [Next Chapter]
Goto Chapter: Top 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 Bib Ind

generated by GAPDoc2HTML