%struct-type
%omit-struct-type
%define hash-function-name gperf_keyword_hash_function
%define lookup-function-name gperf_lookup_keyword
%define word-array-name gperf_keywords
%define constants-prefix GPERF_PARSER_
%define slot-name keyword
%global-table
%null-strings
PARSER_KEYWORD;
%%
#
# Plugins Only Keywords
#
FLUSH,                   97, PARSER_INIT_PLUGINSD,                       WORKER_PARSER_FIRST_JOB + 1
DISABLE,                 98, PARSER_INIT_PLUGINSD,                       WORKER_PARSER_FIRST_JOB + 2
EXIT,                    99, PARSER_INIT_PLUGINSD,                       WORKER_PARSER_FIRST_JOB + 3
HOST,                    71, PARSER_INIT_PLUGINSD,                       WORKER_PARSER_FIRST_JOB + 4
HOST_DEFINE,             72, PARSER_INIT_PLUGINSD,                       WORKER_PARSER_FIRST_JOB + 5
HOST_DEFINE_END,         73, PARSER_INIT_PLUGINSD,                       WORKER_PARSER_FIRST_JOB + 6
HOST_LABEL,              74, PARSER_INIT_PLUGINSD,                       WORKER_PARSER_FIRST_JOB + 7
#
# Common keywords
#
BEGIN,                   12, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 8
CHART,                   32, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 9
CLABEL,                  34, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 10
CLABEL_COMMIT,           35, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 11
DIMENSION,               31, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 12
END,                     13, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 13
FUNCTION,                41, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 14
FUNCTION_RESULT_BEGIN,   42, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 15
LABEL,                   51, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 16
OVERWRITE,               52, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 17
SET,                     11, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 18
VARIABLE,                53, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 19
DYNCFG_ENABLE,          101, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 20
DYNCFG_REGISTER_MODULE, 102, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 21
DYNCFG_REGISTER_JOB,    103, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 22
REPORT_JOB_STATUS,      110, PARSER_INIT_PLUGINSD|PARSER_INIT_STREAMING, WORKER_PARSER_FIRST_JOB + 23
DELETE_JOB,             111, PARSER_INIT_STREAMING,                      WORKER_PARSER_FIRST_JOB + 24
#
# Streaming only keywords
#
CLAIMED_ID,              61, PARSER_INIT_STREAMING,                       WORKER_PARSER_FIRST_JOB + 25
BEGIN2,                   2, PARSER_INIT_STREAMING,                       WORKER_PARSER_FIRST_JOB + 26
SET2,                     1, PARSER_INIT_STREAMING,                       WORKER_PARSER_FIRST_JOB + 27
END2,                     3, PARSER_INIT_STREAMING,                       WORKER_PARSER_FIRST_JOB + 28
#
# Streaming Replication keywords
#
CHART_DEFINITION_END,    33, PARSER_INIT_STREAMING,                       WORKER_PARSER_FIRST_JOB + 29
RBEGIN,                  22, PARSER_INIT_STREAMING,                       WORKER_PARSER_FIRST_JOB + 30
RDSTATE,                 23, PARSER_INIT_STREAMING,                       WORKER_PARSER_FIRST_JOB + 31
REND,                    25, PARSER_INIT_STREAMING,                       WORKER_PARSER_FIRST_JOB + 32
RSET,                    21, PARSER_INIT_STREAMING,                       WORKER_PARSER_FIRST_JOB + 33
RSSTATE,                 24, PARSER_INIT_STREAMING,                       WORKER_PARSER_FIRST_JOB + 34
