range Imagem (gerado) de A^k

## Seqüência de Chamamento

    [X,dim]=range(A,k)

## Parâmetros

A

  matriz de reais ou complexos que se assume quadrada se k>1

k

  inteiro

X

  matriz ortonormal

dim

  inteiro (dimensão de subespaço)

## Descrição

Computação da imagem de `A^k` ; as primeiras dim linhas de `X` geram a imagem de `A^k`. As últimas linhas de `X` geram o complemento ortogonal da imagem. `X*X'` é a matriz identidade.

## Exemplos

    A=rand(4,2)*rand(2,4);   // 4 vetores colunas, 2 independentes.
    [X,dim]=range(A,1);dim   // computando a imagem

    y1=A*rand(4,1);          //um vetor que está na imagem de A
    y2=rand(4,1);            //um vetor que não está na imagem de A
    norm(X(dim+1:$,:)*y1)    //as últimas entradas são zeros, y1 está na imagem de A
    norm(X(dim+1:$,:)*y2)    //as últimas entradas não são zeros

    I=X(1:dim,:)'            //I é uma base para a imagem
    coeffs=X(1:dim,:)*y1     //componentes de y1 relativos à base I

    norm(I*coeffs-y1)        //verificando

## Ver Também

- fullrfk
- rowcomp

## Função Usada

A função `range` é baseada na função rowcomp que usa decomposição svd (decomposição em valores singulares).