varargout variável do número de argumentos de saída em uma lista de argumentos de saída

## Descrição

Uma função cuja lista de argumentos de saída contém `varargout` deve ser chamada com mais argumentos de saída que indicado na lista de argumentos de saída. A chamada de argumentos passados da palavra-chave `varargout` em diante são extraídos da lista `varargout` definida na função.

`varargout = function ex()` pode ser chamado com qualquer número de argumentos de saída. Dentro da função `ex`, argumentos de saída podem ser armazenados em `varargout(i)`.

`[X1,...,Xn,varargout] = function ex()` também pode ser usado. Neste caso, as variáveis `Xi` devem estar atribuídas na função tanto quanto `varargout(i)`.

O número total real de argumentos de saída é dado por `argn(1)`.

`varargout` is by default initialized to `list()`.

## Exemplos

    function varargout = exampl()
        varargout = list(1,2,3,4)
    endfunction

    x = exampl()
    [x, y]    = exampl()
    [x, y, z] = exampl()

    function [a,b,varargout]=exampl1()
        a = 'first'
        b = 'second'
        varargout = list(1,2,3,4)
    endfunction

    exampl1()
    [a, b]  = exampl1()
    [a,b,c] = exampl1()

## Ver Também

- argn
- function
- list
- varargin

## Histórico

6.0.0 varargout is now initialized to list() by default.