black Black図 (ニコルス線図)

## 呼び出し手順

    black( sl,[fmin,fmax] [,step] [,comments] )
                black( sl,frq [,comments] )
                black(frq,db,phi [,comments])
                black(frq,repf [,comments])

## パラメータ

sl

  リスト ( 線形システム `syslin`)

fmin,fmax

  実数スカラー (周波数範囲)

frq

  行ベクトルまたは行列 (周波数)

db,phi

  行ベクトルまたは行列 (絶対値, 位相)

repf

  行ベクトルまたは行列 (複素周波数応答)

step

  実数

comments

  文字列

## 説明

線形システム`sl`のブラック図 (ニコルス線図). `sl` は連続時間または離散時間 SIMOシステム とすることができます(`syslin`参照). 多出力系の場合, 各出力は異なる記号でプロットされます.

The frequencies are given by the bounds 範囲`fmin`,`fmax` (単位: Hz) または行ベクトル`frq` (多出力系の場合は行列) で指定された周波数.

`step` は ( 対数 ) 離散時間刻みです. (デフォルト値の選択については `calfrq` 参照).

`comments`は文字列(キャプション)のベクトル です.

`db,phi` は絶対値 (単位: dB)および 位相 (単位:度)の行列です.

`repf` は複素行列です. 各行は各応答に対応します.

`y/(1+y)`の 等ゲイン,等位相のグリッドをプロットするには, nicholschart()を使用してください.

`fmin` および`fmax` のデフォルト値は, `sl` が連続時間系の場合に `1.d-3`,`1.d+3`, `sl` が離散時間系の場合に`1.d-3`, `0.5`/sl.dt (ナイキスト周波数) となります.

## 例

        //Black diagram
        s=poly(0,'s');
        sl=syslin('c',5*(1+s)/(.1*s.^4+s.^3+15*s.^2+3*s+1))
        clf();black(sl,0.01,10);

s=poly(0,'s'); sl=syslin('c',5*(1+s)/(.1*s.^4+s.^3+15*s.^2+3*s+1)) clf();black(sl,0.01,10);

        //Black diagram with Nichols chart as a grid
        s=poly(0,'s');
        Plant=syslin('c',16000/((s+1)*(s+10)*(s+100)));
        //two degree of freedom PID
        tau=0.2;xsi=1.2;
        PID=syslin('c',(1/(2*xsi*tau*s))*(1+2*xsi*tau*s+tau.^2*s.^2));
        clf();
        black([Plant;Plant*PID ],0.01,100,["Plant";"Plant and PID corrector"]);
        //move the caption in the lower right corner
        ax=gca();Leg=ax.children(1);
        Leg.legend_location="in_lower_right";
        nicholschart(colors=color('light gray')*[1 1])

s=poly(0,'s'); Plant=syslin('c',16000/((s+1)*(s+10)*(s+100))); tau=0.2;xsi=1.2; PID=syslin('c',(1/(2*xsi*tau*s))*(1+2*xsi*tau*s+tau.^2*s.^2)); clf(); black([Plant;Plant*PID ],0.01,100,["Plant";"Plant and PID corrector"]); ax=gca();Leg=ax.children(1); Leg.legend_location="in_lower_right"; nicholschart(colors=color('light gray')*[1 1])

## 参照

- bode
- nyquist
- nicholschart
- freq
- repfreq
- calfrq
- phasemag