mputstr запись отдельного текста в открытый файл

## Синтаксис

                mputstr(str)
                mputstr(str, fid)

## Аргументы

fid

  целое число: идентификатор файла, возвращённый `mopen(…)`. `-1` (по умолчанию) стоит для последнего открытого файла.

str

  Отдельный текст для записи в файл. Принимаются мультиязыковые символы UTF-8. `str` может включать в себя специальные символы форматирования, такие как ascii(9) (табулятор), ascii(10) (новая строка) and ascii(13) (возврат каретки). Такие последовательности, как "\t", "\n" и "\r" не имеют специального значения и записываются как есть.

## Описание

`mputstr(…)` записывает символьную строку `str` в двоичный или текстовый файл. `str` буферизуется: фактически она записывается в файл только при его закрытии.

## Примеры

    myFile = tempname();
    fid = mopen(myFile, "wt");

    mputstr("Scilab", fid);
    mgetl(myFile) // => []. "Scilab" буферизован
    mputstr(" and Xcos", fid);
    mgetl(myFile) // => still []. " and Xcos" добавляется в буфер

    // Только один текст может быть послан за раз:
    mputstr(["Science" ; "Innovation"], fid);     // => error

    mclose(fid);
    mgetl(myFile) // => "Scilab and Xcos"
    mdelete(myFile);

    --> mputstr("Scilab", fid);
    --> mgetl(myFile) // => []. "Scilab"  буферизован
     ans  =
        []

    --> mputstr(" and Xcos", fid);
    --> mgetl(myFile) // => still []. " and Xcos" добавляется в буфер
     ans  =
        []

    --> // Только один текст может быть послан за раз:
    --> mputstr(["Science" ; "Innovation"], fid);    // => error
    mputstr: Argument #1: Scalar (1 element) expected.

    --> mclose(fid);
    --> mgetl(myFile)
     ans  =
      "Scilab and Xcos"

Использование UTF-8 и специальные символы форматирования:

    [tab, nl] = (ascii(9), ascii(10));
    myFile = tempname();
    fid = mopen(myFile, "wt");

    mputstr("Επιστήμη", fid);
    mputstr(ascii(10), fid);      // перевод строки
    mputstr("Τεχνολογία" + nl, fid);
    mputstr(tab, fid);           // табуляция в начале строки
    mputstr("innovation", fid);
    mputstr(nl + "Science" + nl + tab + "technology", fid);
    mclose(fid);
    mgetl(myFile)

    mdelete(myFile);

    --> mputstr("Επιστήμη", fid);
    --> mputstr(ascii(10), fid);      // перевод строки
    --> mputstr("Τεχνολογία" + nl, fid);
    --> mputstr(tab, fid);           // табуляция в начале строки
    --> mputstr("innovation", fid);
    --> mputstr(nl + "Science" + nl + tab + "technology", fid);
    --> mclose(fid);
    --> mgetl(myFile)
     ans  =
      "Επιστήμη"
      "Τεχνολογία"
      "        innovation"
      "Science"
      "        technology"

## Смотрите также

- mgetstr
- mputl
- mgetl
- mput
- mfprintf
- save
- write
- csvWrite