zpk Zero pole gain system representation

## Syntax

              S = zpk(Z, P, K, dt)
              S = zpk(z, p, k, dt)
              S = zpk(sys)

## Arguments

Z

  a m by n cell of real or complex vectors, Z{i,j} is the transmission zeros of the transfer from the the jth intput to the ith output.

P

  a m by n cell of real or complex vectors, P{i,j} is the poles of the transfer from the the jth intput to the ith output.

K

  a m by n matrix of real numbers, K(i,j) is the gain of the transfer from the the jth intput to the ith output.

z

  a real or complex vector, the transmission zeros of the siso transfer function.

p

  a real or complex vector, the poles of the siso transfer function.

k

  a real scalar, the gain of the siso transfer function.

dt

  a character string with possible values "c" or "d", [] or a real positive scalar, the system time domain (see syslin).

sys

  A linear dynamical system in transfer function or state spece representation (see syslin).

S

  a mlist with the fields Z , P, K and dt.

  Z

    a m by n cell array of real or complex vectors, S.Z{i,j} contains the zeros of the transfer from the the jth intput to the ith output

  P

    a m by n cell array of real or complex vectors, S.P{i,j} contains the poles of the transfer from the the jth intput to the ith output

  K

    a m by n matrix of real numbers, S.K(i,j) is the gain of the transfer from the the jth intput to the ith output. output.

  dt

    a positive scalar or "c" or "d" the time domain

## Description

`S=zpk(Z,P,K,dt)` forms the multi-input, multi-output zero pole gain system representation given the cell arrays of the transmission zeros,poles and gain.

`S=zpk(z,p,k,dt)` forms the single-input, single output zero pole gain system representation given the vectors of the transmission zeros and poles and the scalar gain.

`S=zpk(sys)` converts the system representation into a zero-pole-gain representation.

The poles and zeros of each transfer function are sorted in decreasing order of the real part.

Most functions and operations than can act on state-space or rational transfer function representations can be also applied to zero-pole-gain representations.

## Examples

    //Form system from zeros, poles and gain
    //SISO case
    z11=[1 -0.5];p11=[-3+2*%i -3-2*%i  -2];k11=1;
    S11=zpk(z11,p11,k11,"c")

    //MIMO case
    z21=0.3;p21=[-3+2*%i -3-2*%i];k21=1.5;
    S21=zpk(z21,p21,k21,"c")
    S=zpk({z11 [];z21 1},{p11,0;p21 -3},[k11 1;k21 1],"c")

    //system representation conversion
    h=syslin("c",5*(%s^2+2*%s+1)/(%s^2-4))
    sh=zpk(h)

    //operations with zpk representations
    S(1,:)

    S'

    S(1,1)=sh

    sh*S11

    sh./S11

## See Also

- tf2zp
- zpk2tf
- zpk2ss

## History

6.0

Function added.