rational razão de polinômios

## Descrição

Um razão de polinômios `r` é um quociente entre dois polinômios `r=num/den`.

Uma matriz `R` de razãos de polinômios pode ser definida diretamente como o elemento-wise quociente de dois matrizes de polinômios `Num` e `Den`: `R = Num./Den`

A representação interna de uma matriz de razãos de polinômios racional é uma lista do tipo "r": `R=tlist(['r','num','den','dt'], Num, Den, [])`, ou `R = rlist(Num, Den, [])`.

Todos os operadores usuais podem ser aplicados a matrizes de razãos de polinômios : `' .' + - * .* / ./ .^ .*. [,] [;]`,

Quanto aos polinômios, a função `horner()` calcula o valor de razãos para algum valor de sua variável.

Muitas outras funções do Scilab podem ser aplicadas a frações polinomiais : `permute`, `cat`, `real`, `imag`, `conj`, `isreal`, etc.

Endereçando alguns componentes de uma matriz `R` de razãos com seus índices linearizados podem ser feitos usando a sintaxe `R(k,0)` onde `k` é o vetor de índices linearizados, e 0 é usado em vez de índices `j` ou de maior ordem.

## Exemplos

    s=poly(0,'s');
    W=[1/s,1/(s+1)]
    W'*W
    Num=[s,s+2;1,s];Den=[s*s,s;s,s*s];
    rlist(Num,Den,[])
    H=Num./Den
    syslin('c',Num,Den)
    syslin('c',H)
    [Num1,Den1]=simp(Num,Den)

    R = (1-%s).^[1 0 2] ./ %s.^[1 2 0]
    horner(R,[-1 0 2 -2]')

    R = (1-%s)/(1+%s)
    horner(R, 1-%z^2)

    --> R = (1-%s).^[1 0 2] ./ %s.^[1 2 0]
     R  =
                             2
       1 - s   1   1 - 2s + s
       ------  --  -----------
                2
         s     s       1

    --> horner(R,[-1 0 2 -2]')
     ans  =
      -2.    1.     4.
       Inf   Inf    1.
      -0.5   0.25   1.
      -1.5   0.25   9.

    --> R = (1-%s)/(1+%s)
     R  =
       1 - s
       ------
       1 + s

    --> horner(R, 1-%z^2)
     ans  =
          2
         z
       ------
            2
       2 - z

## Ver Também

- poly
- syslin
- horner
- simp

## Histórico

6.0.2 The syntax `R(k,0)` is now available to address components with their linearized indices k.