xstring dessine des chaînes de caractères

## Séquence d'appel

              xstring(x, y, str)
              xstring(x, y, str, angle)
              xstring(x, y, str, angle, box)

## Paramètres

x, y

  vecteurs ou scalaires réel, coordonnées du point en bas à gauche des chaînes de caractères.

str

  matrice de chaînes de caractères.

  A partir de la version Scilab 5.2, il est possible d'utiliser les expressions LaTeX ou MathML

angle

  vecteur ou scalaire réel, angle en degrés dans le sens horaire (0 par défaut).

box

  vecteur ou scalaire entier, 0 par défaut.

## Description

Si `x` est un scalaire, il est considéré comme un vecteur de la taille de `y` dont les éléments ont pour valeur `x`.

Si `y` est un scalaire, il est considéré comme un vecteur de la taille de `x` dont les éléments ont pour valeur `y`.

`xstring` dessine n chaînes de caractères à la position `(x[i], y[i])` dans l'échelle graphique courante.

Si `str` contient n élément, ces n éléments sont les n chaînes de caractères dessinées.

Sinon, chaque ligne de la matrice correspond à une ligne de texte et les éléments d'une ligne sont considérés comme des mots à séparer par un espace.

Si `angle` est un scalaire, il est considéré comme un vecteur de taille n dont les éléments ont pour valeur `angle`.

`angle(i)` définit l'angle en degrés utilisé pour dessiner la chaînes de caractères en position `(x[i], y[i])`.

Si `box` est un scalaire, il est considéré comme un vecteur de taille n dont les éléments ont pour valeur `box`.

Si `box(i)` vaut 1 et que `angle(i)` vaut 0, une boîte est dessinée autour de la chaîne de caractères en position `(x[i], y[i])`.

## Exemples

    plot2d([0;1],[0;1],0)
    xstring(0.5,0.5,["$\overbrace{Scilab}$" "n''est ";"pas" "$\underbrace{Matlab}$"])
    // Rendu LaTeX (>= Scilab 5.2)

    // autre exemple
    alphabet=["a" "b" "c" "d" "e" "f" "g" ..
              "h" "i" "j" "k" "l" "m" "n" ..
              "o" "p" "q" "r" "s" "t" "u" ..
              "v" "w" "x" "y" "z"];
    clf()
    plot2d([0;1],[0;2],0)
    xstring(0.1,1.8,alphabet)     // alphabet
    xstring(0.1,1.6,alphabet,0,1) // alphabet dans une boîte
    xstring(0.1,1.4,alphabet,20)  // angle
    set(gca(), "font_style", 1, "font_size", 1); // police "symbol"
    xstring(0.1,0.1,alphabet)
    xstring(0.1,0.3,alphabet)
    gce().font_size = 3;          // changement de la taille de police
    xstring(0.1,0.6,"a")
    gce().font_size = 24;  // un grand alpha

plot2d([0;1],[0;1],0) xstring(0.5,0.5,["$\overbrace{Scilab}$" "n''est ";"pas" "$\underbrace{Matlab}$"])

## Voir aussi

- text_properties
- Math mode in strings
- xnumb
- xtitle
- titlepage