struct creer une struct

## Séquence d'appel

    st=struct(field1,value1,field2,value2, ...)

## Paramètres

field1, field2, ...

  noms des champs (chaines de caracteres)

value1, value2, ...

  les valeurs des champs (acceptent tous types de données (double, matrice de doubles,des cells, char, ...)

## Description

La fonction `struct` retourne une struct avec des noms de champs `field1`, `field2`, .., et dont les valeurs respectives sont `value1`, `value2`, ...

Notez que `type(st)` retourne `17` et que `typeof(st)` retourne `st`.

## Exemples

    //creer une struct: date les champs sont: 'jour' (valeur: 25), 'mois' (valeur: 'DEC'), 'annee' (valeur: 2006)
    date_st=struct('jour',25,'mois','DEC','annee',2006)

    // changer la valeur des champs
    date_st.jour=19;
    date_st.mois='AOU';
    date_st.annee=1973;

    // ajouter un champ 'semaine'
    date_st.semaine=32

    //creation d'une structure test
    test=struct('list1',list('testlist',1,2), 'matrix1', [1 2 3; 4 5 6], 'boolean1', %t);
    //ajout d'un polynôme
    s=poly(0,'s')
    test.pol1=s;
    //ajout d'un système linéaire (représentation d'état)
    A=[0,1;0,0]; B=[1;1];C=[1,1];
    test.ss1=syslin('c',A,B,C);
    //Affichage de la liste
    test.list1
    getfield(3,test)
    //Affichage du type
    type(test)

## Voir aussi

- cell
- mlist
- tlist
- getfield
- setfield