swap_handles Permuta dois manipuladores em uma hierarquia gráfica

## Seqüência de Chamamento

    swap_handle( handle1, handle2 )

## Parâmetros

handle1

  primeiro manipulador da permutação

handle2

  segundo manipulador da permutação

## Descrição

A função swap_handles permite permutar dois manipuladores em uma hierarquia gráfica. O primeiro manipulador tomará a posição do segundo e vice-versa.

Desde que nem todos os manipuladores são compatíveis com cada um dos outros, existem algumas restrições ao se trocar manipuladores. Por exemplo, não é permitido trocar um manipulador Polyline com um manipulador Axes, já que não seriam compatíveis com suas novas raízes. Mais informação sobre compatibilidade pode ser encontrada na página graphics_entities.

Esta rotina pode ser utilizada em galhos com uma mesma raiz para se trocar os seus índices.

## Exemplos

    //-----------------//
    // Primeiro Exemplo//
    //-----------------//

    // criando um retângulo
    xrect( 0.5, 0.5,0.5,0.5) ;
    rect = gce() ;

    // criando um círculo
    xarc( 0.5, 0.5, 0.5, 0.5, 0, 64 * 360 ) ;
    circle = gce() ;

    // criando uma seta
    xpoly([0,1],[0,1]) ;
    arrow = gce() ;
    arrow.polyline_style = 4 ;
    arrow.arrow_size_factor = 4 ;

    // obtendo a lista de galhos
    axes = gca()  ;
    axes.children

    // mudando a ordem
    swap_handles( rect, arrow ) ;
    swap_handles( arrow, circle ) ;

    // obtendo a nova ordem
    axes.children

    //-----------------//
    //  Segundo Exemplo//
    //-----------------//

    // criando duas janelas
    plot2d ;
    axes1 = gca() ;

    scf() ;
    fec ;
    axes2 = gca() ;

    // trocando os seus eixos
    // note que o mapa de cores não muda.
    swap_handles( axes1, axes2 ) ;

## Ver Também

- graphics_entities
- copy
- delete