close closes graphic figures, progressionbars or waitbars

## Syntax

                close
                close(H)

## Arguments

H

  Handle or vector of handles of graphic figures or progression bar or wait bar. These different types of handles can be mixed in `H`.

  By default, the current graphic figure is considered.

## Description

Graphic windows based on the Tk technology (such as still used by imshow() in the SIVP external module) may be closed as well by providing their number that is their handle.

## Examples

    // creates  figure number 1.
    h = scf();
    // put a clever text in figure 1
    uicontrol( h, 'style','text', ...
                  'string','scilab is great', ...
                  'position',[50 70 100 100], ...
                  'fontsize',15);
    // create figure 2
    scf();
    // put a text in figure 2
    uicontrol( 'style','text', ...
               'string','Really great', 'position',[50 70 100 100], 'fontsize',15);

    close();   // close the current graphic window (ie fig. 2)
    close(h);  // close figure 1

    // create a progression bar
    wid1=progressionbar("Message");
    // close it
    close(wid1);

## See also

- xdel
- delete
- figure
- scf
- gcf