debug Environnement de débogage dans Scilab

## Séquence d'appel

                debug()

## Description

Cet environnement sert à débogger un cript Scilab. Après l'appel à `debug()`, vous entrez en mode debogage. Ce mode vous permet de manipuler des points d'arrêts, de lancer des exécutions avec arrêt sur erreur, d'exécuter des scripts en mode pas à pas ... Dans la console, ce mode est indiqué par l'invite `debug>`.

Commandes:
- h:

  Affiche l'aide du débogueur dans la console, quel que soit le mode de lancement de Scilab.

  help:

  En mode Scilab standard (avec fenêtres et interfaces graphiques), ouvre le navigateur d'aide. Sinon affiche l'aide du debogueur dans la console (comme avec "h").

  (q)uit:

  Quitte l'environnement de débogage et revient au mode normal de Scilab.

  (w)here ou bt:

  Affiche la pile d'appel.

  (e)xec, ou (r)un:

  Exécute une commande.

  (d)isp var, ou (p)rint var:

  Affiche la variable `var`.

  (c)ontinue:

  Poursuit l'éxécution.

  (a)bort:

  Annule l'éxécution.

  step(n)ext ou next:

  Poursuit l'éxécution jusqu'a l'expression suivante.

  step(i)n ou in:

  Poursuit l'éxécution dans la sous fonction.

  step(o)ut ou out:

  Poursuit l'éxécution jusqu'à revenir dans la fonction appelante.

  (b)reakpoint ou break:

      breakpoint function [line [condition]]

  Ajoute un point d'arrêt dans une fonction, à la ligne `line` indiquée.

  Si une condition est spécifiée, le point d'arrêt devient actif uniquement si la condition est vérifiée.

  (del)ete [n]:

  Supprime tous les points d'arrêt.

  Si n est spécifié, supprime le point d'arrêt #n

  enable [n]:

  Active tous les points d'arrêt.

  Si n est spécifié, active le point d'arrêt #n

  disable [n]:

  Désactive tous les points d'arrêt.

  Si n est spécifié, désactive le point d'arrêt #n

  (s)how [n]:

  Affiche toutes les informations sur les points d'arrêt.

  Si n est spécifié, affiche les informations du point d'arrêt #n

## Exemples

    //fonction de surcharge de la fonction cosinus pour les chaînes de caractères
    function v = %c_cos(val)
        printf("val : %s\n", val);
        v = cos(evstr(val));
    endfunction

    //appelant
    function a = test_debug()
        b = cos("%pi");
        a = b * 3;
    endfunction

    debug
    break test_debug
    exec test_debug
    where
    stepin
    disp val
    continue
    quit

    function v = compute(val)
        v = 1;
        for i=1:val
            v = v * i;
        end
    endfunction

    debug
    break compute 4 "i == 5"
    exec compute(10)
    disp val
    disp i
    disp v
    continue
    quit

## Historique

6.0.0 Introduction du débogueur intégré, en interface console