saveGui Save a graphic user interface in a file

## Syntax

    saveGui(fig, filename)

## Arguments

fig

  handle, the handle of the current figure

filename

  character string containing the path of the file

## Description

The `saveGui` function can be used to save a graphic user interface in a file and reloaded by the `loadGui` function.

`saveGui(f, filename)` save a current graphic handle f in file defined by `filename`. If the operation failed an error message in the Scilab console will be printed.

## Examples

    // First example
    f = figure("background", -2);
    h = uicontrol(f, "style", "text", ...
                  "string", "This is a figure", ...
                  "position", [210 180 300 100], ...
                  "fontsize", 24, ...
                  "backgroundcolor", [1 1 1]);

    saveGui(f, fullfile(TMPDIR, "foo"))
    close(f)
    loadGui(fullfile(TMPDIR, "foo"));

    // Second example
    f = figure("default_axes", "off", ...
               "dockable", "off", ...
               "figure_name", "Sélection", ...
               "axes_size", [200 200], ...
               "infobar_visible", "off", ...
               "menubar_visible", "off", ...
               "toolbar", "none", ...
               "toolbar_visible", "off", ...
               "layout", "gridbag");

    h1 = uicontrol(f, "style", "text", ...
                    "string", "Following List :", ...
                    "fontsize", 15, ...
                    "constraints", createConstraints("gridbag", [1 1 2 1], [1 0], "both"));

    h2 = uicontrol(f, "style", "popupmenu", ...
                    "string", ["item1"; "item2"; "item3"], ...
                    "value", 1, ...
                    "fontsize", 15, ...
                    "constraints", createConstraints("gridbag", [1 2 2 1], [1 0], "both"), ...
                    "tag", "selection");

    h3 = uicontrol(f, "style", "pushbutton", ...
                    "string", "OK", ...
                    "callback", "obj = findobj(""tag"", ""selection""); mprintf(""La valeur sélectionnée est : %s.\n"", obj.string(obj.value)); close(gcf())", ...
                    "fontsize", 15, ...
                    "constraints", createConstraints("gridbag", [1 3 1 1], [1 0], "both", "left"));

    h4 = uicontrol(f, "style", "pushbutton", ...
                    "string", "CANCEL", ...
                    "callback", "close(gcf())", ...
                    "fontsize", 15, ...
                    "constraints", createConstraints("gridbag", [2 3 1 1], [1 0], "both", "right"));

    saveGui(f, "TMPDIR/foo2.xml");
    close(f)
    loadGui("TMPDIR/foo2.xml")

## See also

- loadGui
- load
- save

## History

5.5.0 Function `saveGui` introduced.