error relata um erro de tempo de execução

## Seqüência de Chamamento

                error(message)
                error(message, n)
                error(n, message)

## Parâmetros

message

  Vetor de strings: A mensagem de erro a ser exibida. Cada componente é exibido em uma linha separada. Fornecer uma mensagem de erro traduzida com `gettext(…)` é uma boa prática.

n

  integer> 0: identificador numérico atribuído ao erro. Padrão = 10000. Embora a mensagem seja geralmente traduzida no idioma da sessão atual, `n` permite testar o erro de maneira independente do idioma.

## Descrição

`error` permite escrever uma mensagem de erro e manipular o erro. Por padrão, `error`

- interrompe a execução corrente,
- exibe no console a árvore de chamada recursiva que leva ao erro,
- exibe o a mensagem de error `message`,
- e retorna ao nível de prompt.

Para lidar com o erro sem interromper a execução, é possível capturá-lo usando `try … catch` ou `execstr(…,'errcatch')`, e para testá-lo com `lasterror(…)`.

`error(message)` exibe o número 10000 e string contido em `message`.

`error(message,n)` imprime o string contido em `message`. O número associado à erro é dado por n.

Ver error_table para uma lista das mensagens padrão de erro.

## Exemplos

    function test(a)
        if argn(2)~=1
            msg = gettext("%s: Wrong number of input arguments: %d expected.\n")
            error(msprintf(msg, "test", 1))
        end
    endfunction
    function myfun()
        a = 1;
        test()
    endfunction

    // ----------

    error(['A multi line' 'error message'])
    error(500, 'Error: my error message')
    [m, n] = lasterror()

    test()
    myfun()

    --> error(['A multi line' 'error message'])

    A multi line
    error message

    --> error(500, 'Error: my error message')

    Error: my error message

    --> [m, n] = lasterror()
     n  =
       500.
     m  =
     Error: my error message

    --> test()
    at line     4 of function test

    test: Quantidade incorreta de argumentos de entrada: esperava-se 1.

    --> myfun()
    at line     4 of function test
    at line     3 of function myfun

    test: Quantidade incorreta de argumentos de entrada: esperava-se 1.

## Ver Também

- lasterror
- error_table
- gettext
- warning
- try
- execstr
- where

## Histórico

5.0.0 `error(n, message)` syntax introduced.
5.4.0 The `error` function can take vector of strings as input argument.
6.0.0 The `error(n)` and `error(n, pos)` syntaxes are no longer supported: Providing an explicit error message is now mandatory. There is no longer any absolute error identifier.